AI Control Keybinds

addons/common/XEH_PREP.hpp

@@ -17,6 +17,7 @@ PREP(getActiveTree);
 PREP(getAllTurrets);
 PREP(getArtilleryETA);
 PREP(getCargoPositionsCount);
+PREP(getCursorPosition);
 PREP(getDefaultInventory);
 PREP(getDLC);
 PREP(getLightingSelections);

addons/common/functions/fnc_getCursorPosition.sqf

@@ -0,0 +1,38 @@
+#include "script_component.hpp"
+/*
+ * Author: Ampersand
+ * Returns ASL position of curator cursor.
+ * If cursor is over an object or building, the surface intersection position is returned.
+ * If the curator map is open, the ground level position is returned.
+ *
+ * Arguments:
+ * None
+ *
+ * Return Value:
+ * Position ASL <ARRAY>
+ *
+ * Example:
+ * [] call zen_common_fnc_getCursorPosition
+ *
+ * Public: No
+ */
+
+ if (ctrlShown ((findDisplay 312) displayCtrl 50)) then {
+     // Curator map
+     private _pos2d = (((findDisplay 312) displayCtrl 50) ctrlMapScreenToWorld getMousePosition);
+     _pos2d set [2, getTerrainHeightASL _pos2d];
+     _pos2d
+ } else {
+     // Check elevated position
+     private _pos3d = AGLToASL (screenToWorld getMousePosition);
+     private _position0 = AGLToASL positionCameraToWorld [0, 0, 0];
+     private _intersections = lineIntersectsSurfaces [_position0, _pos3d, cameraOn, objNull, true, 1, "GEOM"];
+
+     if !(_intersections isEqualTo []) then {
+         (_intersections # 0) params ["_intersectPosASL", "", "_intersectObject", ""];
+         if !(isNull _intersectObject) then {
+             _pos3d = _intersectPosASL;
+         };
+     };
+     _pos3d
+ };

addons/editor/initKeybinds.sqf

@@ -82,3 +82,60 @@
         };
     };
 }, {}, [0, [false, false, false]]] call CBA_fnc_addKeybind; // Default: Unbound
+
+[ELSTRING(main,DisplayName), QGVAR(watchCursor), [LSTRING(WatchCursor), LSTRING(WatchCursor_Description)], {
+    if (!isNull curatorCamera && {!GETMVAR(RscDisplayCurator_search,false)}) then {
+        curatorMouseOver params ["_type", "_entity", "_index"];
+        private _isCancelling = (_type == "OBJECT") && {_entity in SELECTED_OBJECTS};
+        private _gunners = (SELECTED_OBJECTS apply {gunner vehicle _x}) - [objNull];
+
+        private _cursorPosASL = call EFUNC(common,getCursorPosition);
+        {
+            [QEGVAR(common,doWatch), [_x, [ASLToAGL _cursorPosASL, objNull] select _isCancelling], _x] call CBA_fnc_targetEvent;
+        } forEach _gunners;
+
+        true // handled, prevents vanilla eject
+    };
+}, {}, [0, [false, false, false]]] call CBA_fnc_addKeybind; // Default: Unbound
+
+[ELSTRING(main,DisplayName), QGVAR(moveToCursor), [LSTRING(MoveToCursor), LSTRING(MoveToCursor_Description)], {
+    if (!isNull curatorCamera && {!GETMVAR(RscDisplayCurator_search,false)}) then {
+        private _cursorPosASL = call EFUNC(common,getCursorPosition);
+
+        {
+            if (!isNull driver _x) then {
+                [QEGVAR(common,doMove), [_x, ASLToAGL _cursorPosASL], _x] call CBA_fnc_targetEvent;
+            };
+        } forEach SELECTED_OBJECTS;
+
+        true // handled, prevents vanilla eject
+    };
+}, {}, [0, [false, false, false]]] call CBA_fnc_addKeybind; // Default: Unbound
+
+[ELSTRING(main,DisplayName), QGVAR(toggleAIPATH), [LSTRING(ToggleAIPATH), LSTRING(ToggleAIPATH_Description)], {
+    if (!isNull curatorCamera && {!GETMVAR(RscDisplayCurator_search,false) && {count SELECTED_OBJECTS > 0}}) then {
+        private _disabled = 0;
+        private _enabled = 0;
+        private _drivers = (SELECTED_OBJECTS apply {driver vehicle _x}) - [objNull];
+        _drivers = _drivers arrayIntersect _drivers;
+
+        {
+            private _isAIEnalbedPATH = _x getVariable [QEGVAR(common,isAIEnalbedPATH), true];
+            private _AIEvent = [QEGVAR(common,enableAI), QEGVAR(common,disableAI)] select _isAIEnalbedPATH;
+            [_AIEvent, [_x, "PATH"], _x] call CBA_fnc_targetEvent;
+            _x setVariable [QEGVAR(common,isAIEnalbedPATH), !_isAIEnalbedPATH, true];
+            if (_isAIEnalbedPATH) then {
+                _disabled = _disabled + 1;
+            } else {;
+                _enabled = _enabled + 1;
+            };
+        } forEach _drivers;
+
+        private _message = "PATH " +
+            (["", format [" - disabled: %1", _disabled]] select (_disabled > 0)) +
+            (["", format [" - enabled: %1", _enabled]] select (_enabled > 0));
+        [_message] call EFUNC(common,showMessage);
+
+        true // handled, prevents vanilla eject
+    };
+}, {}, [0, [false, false, false]]] call CBA_fnc_addKeybind; // Default: Unbound

addons/editor/stringtable.xml

@@ -219,5 +219,23 @@
             <Japanese>全編集可アイコンの視認性を切り替えます。一時的な処理軽減や整理に使用できます。</Japanese>
             <Polish>Przełącza widoczność wszsytkich ustawionych ikon, przydatne by tymczasowo zmniejszyć lag, bądź niepotrzebne zaśmiecenie ekranu gdy znajduje się na nim dużo ikon.</Polish>
         </Key>
+        <Key ID="STR_ZEN_Editor_WatchCursor">
+            <English>Watch Cursor</English>
+        </Key>
+        <Key ID="STR_ZEN_Editor_WatchCursor_Description">
+            <English>Makes all selected units watch the cursor location. Pressing this command with the cursor over a selected unit will cancel the watch target.</English>
+        </Key>
+        <Key ID="STR_ZEN_Editor_MoveToCursor">
+            <English>Move To Cursor</English>
+        </Key>
+        <Key ID="STR_ZEN_Editor_MoveToCursor_Description">
+            <English>Makes all selected units move to the cursor location. Units will return to formation and waypoint afterward.</English>
+        </Key>
+        <Key ID="STR_ZEN_Editor_ToggleAIPATH">
+            <English>Toggle AI PATH</English>
+        </Key>
+        <Key ID="STR_ZEN_Editor_ToggleAIPATH_Description">
+            <English>Makes all selected units start or stop moving. Does not affect aiming or shooting.</English>
+        </Key>
     </Package>
 </Project>