Fix File#truncate and #lock for Win32 append-mode files

spec/std/file_spec.cr

@@ -1049,6 +1049,41 @@ describe "File" do
     end
   end
 
+  it "does not overwrite existing content in append mode" do
+    with_tempfile("append-override.txt") do |filename|
+      File.write(filename, "0123456789")
+
+      File.open(filename, "a") do |file|
+        file.seek(5)
+        file.write "abcd".to_slice
+      end
+
+      File.read(filename).should eq "0123456789abcd"
+    end
+  end
+
+  it "truncates file opened in append mode (#14702)" do
+    with_tempfile("truncate-append.txt") do |path|
+      File.write(path, "0123456789")
+
+      File.open(path, "a") do |file|
+        file.truncate(4)
+      end
+
+      File.read(path).should eq "0123"
+    end
+  end
+
+  it "locks file opened in append mode (#14702)" do
+    with_tempfile("truncate-append.txt") do |path|
+      File.write(path, "0123456789")
+
+      File.open(path, "a") do |file|
+        file.flock_exclusive { }
+      end
+    end
+  end
+
   it "can navigate with pos" do
     File.open(datapath("test_file.txt")) do |file|
       file.pos = 3

src/crystal/system/unix/file.cr

@@ -24,6 +24,9 @@ module Crystal::System::File
     {fd, fd < 0 ? Errno.value : Errno::NONE}
   end
 
+  protected def system_set_mode(mode : String)
+  end
+
   def self.info?(path : String, follow_symlinks : Bool) : ::File::Info?
     stat = uninitialized LibC::Stat
     if follow_symlinks

src/crystal/system/wasi/file.cr

@@ -2,6 +2,9 @@ require "../unix/file"
 
 # :nodoc:
 module Crystal::System::File
+  protected def system_set_mode(mode : String)
+  end
+
   def self.chmod(path, mode)
     raise NotImplementedError.new "Crystal::System::File.chmod"
   end

src/crystal/system/win32/file.cr

@@ -9,6 +9,8 @@ require "c/ntifs"
 require "c/winioctl"
 
 module Crystal::System::File
+  @system_append = false
+
   def self.open(filename : String, mode : String, perm : Int32 | ::File::Permissions) : FileDescriptor::Handle
     perm = ::File::Permissions.new(perm) if perm.is_a? Int32
     # Only the owner writable bit is used, since windows only supports
@@ -52,10 +54,9 @@ module Crystal::System::File
                LibC::FILE_GENERIC_READ
              end
 
-    if flags.bits_set? LibC::O_APPEND
-      access |= LibC::FILE_APPEND_DATA
-      access &= ~LibC::FILE_WRITE_DATA
-    end
+    # do not handle `O_APPEND`, because Win32 append mode relies on removing
+    # `FILE_WRITE_DATA` which breaks file truncation and locking; instead,
+    # simply set the end of the file as the write offset in `#write_blocking`
 
     if flags.bits_set? LibC::O_TRUNC
       if flags.bits_set? LibC::O_CREAT
@@ -96,6 +97,24 @@ module Crystal::System::File
     {access, disposition, attributes}
   end
 
+  protected def system_set_mode(mode : String)
+    @system_append = true if mode.starts_with?('a')
+  end
+
+  private def write_blocking(handle, slice)
+    if @system_append
+      write_blocking(handle, slice) do
+        overlapped = LibC::OVERLAPPED.new
+        overlapped.union.offset.offset = 0xFFFFFFFF_u32
+        overlapped.union.offset.offsetHigh = 0xFFFFFFFF_u32
+        ret = LibC.WriteFile(handle, slice, slice.size, out bytes_written, pointerof(overlapped))
+        {ret, bytes_written}
+      end
+    else
+      super
+    end
+  end
+
   NOT_FOUND_ERRORS = {
     WinError::ERROR_FILE_NOT_FOUND,
     WinError::ERROR_PATH_NOT_FOUND,

src/crystal/system/win32/file_descriptor.cr

@@ -54,8 +54,8 @@ module Crystal::System::FileDescriptor
     end
   end
 
-  private def write_blocking(handle, slice)
-    ret = LibC.WriteFile(handle, slice, slice.size, out bytes_written, nil)
+  private def write_blocking(handle, slice, &)
+    ret, bytes_written = yield
     if ret.zero?
       case error = WinError.value
       when .error_access_denied?
@@ -69,6 +69,13 @@ module Crystal::System::FileDescriptor
     bytes_written
   end
 
+  private def write_blocking(handle, slice)
+    write_blocking(handle, slice) do
+      ret = LibC.WriteFile(handle, slice, slice.size, out bytes_written, nil)
+      {ret, bytes_written}
+    end
+  end
+
   # :nodoc:
   def system_blocking?
     @system_blocking

src/file.cr

@@ -173,7 +173,7 @@ class File < IO::FileDescriptor
   def self.new(filename : Path | String, mode = "r", perm = DEFAULT_CREATE_PERMISSIONS, encoding = nil, invalid = nil, blocking = true)
     filename = filename.to_s
     fd = Crystal::System::File.open(filename, mode, perm: perm)
-    new(filename, fd, blocking: blocking, encoding: encoding, invalid: invalid)
+    new(filename, fd, blocking: blocking, encoding: encoding, invalid: invalid).tap { |f| f.system_set_mode(mode) }
   end
 
   getter path : String