How to use springboot-customized-webapp with gradle?

[MarvinKern]

Hi,
I am currently trying to translate the pom.xml to a build.gradle, but I am not sure how to transfer the plugin parts.
Is there already somewhere a springboot customized webapp implemented with gradle?
Thank you :)
Kind regards,
Marvin

[MarvinKern]

What I got for now:

plugins {
    id 'java'
    id 'maven-publish'
}

repositories {
    mavenLocal()
    maven {
        url = 'http://repo.maven.apache.org/maven2'
    }
}

dependencies {
    implementation 'XXX:XXX:1.0.0'
}

group = 'XXX'
version = '1.0.0-SNAPSHOT'
sourceCompatibility = '1.8'

publishing {
    publications {
        maven(MavenPublication) {
            from(components.java)
        }
    }
}

[marketmi]

Hi @MarvinKern.
This is what we came up with:

plugins {
    id 'java'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation "org.camunda.bpm.webapp:camunda-webapp:$rootProject.ext.camundaVersion"
    implementation "org.camunda.bpm.webapp:camunda-webapp-webjar:$rootProject.ext.camundaVersion"
}

group = 'XXX'
sourceCompatibility = '11'

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

task copyLibs(type: Copy) {
    from {
        configurations.compileClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
    include 'META-INF/resources/**'
    exclude '**/user*.css'
    into "$buildDir/resources/main"
}

task copyArtWorkIntoTasklistImages(type: Copy) {
    from "artwork"
    into "$buildDir/resources/main/META-INF/resources/webjars/camunda/app/tasklist/assets/images"
}

task copyArtWorkIntoCockpitImages(type: Copy) {
    from "artwork"
    into "$buildDir/resources/main/META-INF/resources/webjars/camunda/app/cockpit/assets/images"
}

task copyArtWorkIntoAdminImages(type: Copy) {
    from "artwork"
    into "$buildDir/resources/main/META-INF/resources/webjars/camunda/app/admin/assets/images"
}

task copyArtWorkIntoWelcomeImages(type: Copy) {
    from "artwork"
    into "$buildDir/resources/main/META-INF/resources/webjars/camunda/app/welcome/assets/images"
}

processResources {
    dependsOn copyLibs
    dependsOn copyArtWorkIntoAdminImages
    dependsOn copyArtWorkIntoCockpitImages
    dependsOn copyArtWorkIntoTasklistImages
    dependsOn copyArtWorkIntoWelcomeImages
}