opx

.PAGE 'OPEN CHANNEL'
;
; OPEN A READ CHANL WITH 2 BUFFERS
; WILL INSERT SA IN LINTAB
; AND INITS ALL POINTERS.
; RELATIVE SS AND PTRS ARE SET.
;
OPNRCH
	LDA #2          ; GET TWO DATA BUFFERS
	JSR GETRCH
	JSR INTPNT      ; CLEAR POINTERS
	LDA TYPE
	PHA
	ASL A
	ORA DRVNUM
	STA FILTYP,X    ; SET FILE TYPE
	JSR STRDBL      ; READ ONE OR TWO BLOCKS
	LDX LINDX
	LDA TRACK
	BNE OR10
	LDA SECTOR
	STA LSTCHR,X    ; SET LAST CHAR PTR
OR10
	PLA
	CMP #RELTYP
	BNE OR30        ; MUST BE SEQUENTIAL STUFF
	LDY SA
	LDA LINTAB,Y    ; SET CHANNEL AS R/W
	ORA #$40
	STA LINTAB,Y
	LDA REC
	STA RS,X        ; SET RECORD SIZE
	JSR GETBUF      ; GET SS BUFFER
	BPL OR20
	JMP GBERR       ; NO BUFFER
OR20
	LDX LINDX
	STA SS,X
	LDA TRKSS
	STA SSSTRK,X
	LDA SECSS
	STA SSSSEC,X
	LDA #255
	STA SSSGRP,X    ; NO GROUP RESIDENT
OROW
	LDX LINDX
	LDA #2
	STA NR,X        ; SET FOR NXTREC
	LDA #0
	JSR SETPNT      ; SET FIRST DATA BYTE
	JSR RD40        ; SET UP 1ST RECORD
	JMP GETHDR      ; RESTORE TRACK AND SECTOR
OR30
	JSR RDBYT       ; SEQUENTIAL SET UP
	LDX LINDX
	STA CHNDAT,X
	LDA #RDYTLK
	STA CHNRDY,X
	RTS
;
; INITIALIZE VARIABLES FOR OPEN CHANL
; LSTJOB,SETS ACTIVE BUFFER#,LSTCHR,
; BUFFER POINTERS IN BUFTAB = 2
;
INTPNT
	LDX LINDX
	LDA DRVNUM
	LDY BUF0,X
	STA LSTJOB,Y
	LDY BUF1,X
	STA LSTJOB,Y
	STA JOBS,Y
	LDA BUF0,X
	ASL A
	TAY
	LDA #2
	STA BUFTAB,Y
	LDA BUF1,X
	ORA #$80
	STA BUF1,X
	ASL A
	TAY
	LDA #2
	STA BUFTAB,Y
	LDA #0
	STA NBKL,X
	STA NBKH,X
	LDA #0
	STA LSTCHR,X
	RTS
;
; OPEN A WRITE CHANL WITH 2 BUFFERS
;
OPNWCH
	JSR INTTS       ; GET FIRST TRACK, SECTOR
	LDA #2
	JSR GETWCH      ; GET 2 BUFFERS FOR WRITING
	JSR SETHDR      ; SET UP BUFFER HEADERS
	JSR INTPNT
	LDX LINDX
	LDA TYPE
	PHA
	ASL A
	ORA DRVNUM
	STA FILTYP,X    ; SET FILTYP = SEQ
	PLA
	CMP #RELTYP
	BEQ OW10
	LDA #RDYLST     ; ACTIVE LISTENER
	STA CHNRDY,X
	RTS
OW10
	LDY SA
	LDA LINTAB,Y
	AND #$3F
	ORA #$40
	STA LINTAB,Y    ; SET CHANNEL AS R/W
	LDA REC
	STA RS,X        ; SET RECORD SIZE
	JSR GETBUF      ; GET SS BUFFER
	BPL OW20
	JMP GBERR       ; NO BUFFER
OW20
	LDX LINDX
	STA SS,X
	JSR CLRBUF
	JSR NXTTS
	LDA TRACK
	STA TRKSS       ; SAVE SS TRACK AND SECTOR
	LDA SECTOR
	STA SECSS
	LDX LINDX
	LDA SS,X
	JSR SETH        ; SET SS HEADER
	LDA #0
	JSR SETSSP
	LDA #0          ; SET NULL LINK
	JSR PUTSS
	LDA #SSIOFF+1   ; SET LAST CHAR
	JSR PUTSS
	LDA #0          ; SET THIS SS #
	JSR PUTSS
	LDA REC         ; RECORD SIZE
	JSR PUTSS
	LDA TRACK
	JSR PUTSS
	LDA SECTOR
	JSR PUTSS
	LDA #SSIOFF
	JSR SETSSP
	JSR GETHDR      ; GET FIRST TRACK AND SECTOR
	LDA TRACK
	JSR PUTSS
	LDA SECTOR
	JSR PUTSS
	JSR WRTSS       ; WRITE IT OUT
	JSR WATJOB
	LDX LINDX
	LDA SS,X        ; GET SS BUFFER #
	JSR CLRBUF      ; CLEAR THAT BUFFER
	JSR SETSSP      ; SET SIDE SECTOR POINTER
	LDA TRKSS
	JSR PUTSS       ; SET TRACK LINK
	LDA SECSS
	JSR PUTSS       ; SET SECTOR LINK
	LDA #254
	JSR PUTSS       ; SET SUPER SS ID
	LDA TRKSS
	JSR PUTSS       ; SET TRACK SS LINK
	LDA SECSS
	JSR PUTSS       ; SET SECTOR SS LINK
	JSR NXTTS       ; GET NEXT TRACK AND SECTOR
	LDX LINDX
	LDA TRACK
	STA SSSTRK,X    ; SAVE SSS TRACK
	STA TRKSS
	LDA SECTOR
	STA SSSSEC,X    ; SAVE SSS SECTOR
	STA SECSS
	LDA #255
	STA SSSGRP,X    ; NO RESIDENT SS
	JSR WRTSSS      ; WRITE THE SUPER SIDE SECTOR
	JSR GETHDR
OW21
	LDA #2
	JSR SETPNT
	LDX LINDX       ; SET NR FOR NULL BUFFER
	SEC
	LDA #0
	SBC RS,X
	STA NR,X
	JSR NULBUF      ; NULL RECORDS
	JSR NULLNK
	JSR WRTOUT
	JSR WATJOB
	JSR MAPOUT      ; WRITE THE BAM
	JMP OROW
;
; PUT BYTE INTO SIDE SECTOR
;
PUTSS
	PHA
	LDX LINDX
	LDA SS,X
	JMP PUTB1
.END