forked from kubernetes-el/kubernetes-el
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathkubernetes-jobs.el
180 lines (151 loc) · 7.13 KB
/
kubernetes-jobs.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
;;; kubernetes-jobs.el --- Rendering for Kubernetes jobs. -*- lexical-binding: t; -*-
;;; Commentary:
;;; Code:
(require 'dash)
(require 'kubernetes-ast)
(require 'kubernetes-kubectl)
(require 'kubernetes-modes)
(require 'kubernetes-pod-line)
(require 'kubernetes-props)
(require 'kubernetes-state)
(require 'kubernetes-utils)
(require 'kubernetes-vars)
(require 'kubernetes-yaml)
;; Components
(defconst kubernetes-jobs--column-heading
["%-45s %10s %6s" "Name Successful Age"])
(kubernetes-ast-define-component job-detail (state pod job)
(-let* (((&alist 'metadata (&alist 'namespace ns
'creationTimestamp time)
'spec (&alist 'template
(&alist 'spec (&alist 'restartPolicy restart-policy)))
'status (&alist
'startTime start-time
'completionTime completion-time))
job)
((&alist 'items pods) (kubernetes-state--get state 'pods)))
`((section (namespace nil)
(nav-prop (:namespace-name ,ns)
(key-value 12 "Namespace" ,(propertize ns 'face 'kubernetes-namespace))))
,(when restart-policy
`(key-value 12 "RestartPolicy" ,restart-policy))
(padding)
(key-value 12 "Created" ,time)
,(when start-time
`(key-value 12 "Started" ,start-time))
,(when completion-time
`(key-value 12 "Completed" ,completion-time))
(padding)
(section (pod nil)
(heading "Pod")
(indent
(membership-loading-container ,pod ,pods
(pod-line ,state ,pod)
(padding)))))))
(kubernetes-ast-define-component job-line (state pod job)
(-let* ((current-time (kubernetes-state-current-time state))
(pending-deletion (kubernetes-state--get state 'jobs-pending-deletion))
(marked-jobs (kubernetes-state--get state 'marked-jobs))
((&alist 'metadata (&alist 'name name 'creationTimestamp created-time)
'status (&alist 'succeeded successful
'completionTime completion-time))
job)
(successful (or successful 0))
([fmt] kubernetes-jobs--column-heading)
(list-fmt (split-string fmt))
(line (concat
;; Name
(let ((name-str (format (pop list-fmt) (kubernetes-utils-ellipsize name 43))))
(cond
((and completion-time (< 0 successful))
(propertize name-str 'face 'kubernetes-dimmed))
((not (kubernetes-pod-line-ok-p pod))
(propertize name-str 'face 'warning))
(t
name-str)))
" "
;; Successful
(propertize (format (pop list-fmt) successful) 'face 'kubernetes-dimmed)
" "
;; Age
(let ((start (apply #'encode-time (kubernetes-utils-parse-utc-timestamp created-time))))
(propertize (format (pop list-fmt) (kubernetes-utils-time-diff-string start current-time))
'face 'kubernetes-dimmed)))))
`(nav-prop (:job-name ,name)
(copy-prop ,name
(line ,(cond
((member name pending-deletion)
`(propertize (face kubernetes-pending-deletion) ,line))
((member name marked-jobs)
`(mark-for-delete ,line))
(t
line)))))))
(defun kubernetes-jobs--lookup-pod-for-job (job state)
(-let* (((&alist 'metadata (&alist 'labels (&alist 'job-name job-name))) job)
((&alist 'items items) (kubernetes-state--get state 'pods)))
(seq-find (lambda (pod)
(let ((pod-name (kubernetes-state-resource-name pod)))
(string-prefix-p job-name pod-name)))
items)))
(kubernetes-ast-define-component job (state job)
(let ((pod (kubernetes-jobs--lookup-pod-for-job job state)))
`(section (,(intern (kubernetes-state-resource-name job)) t)
(heading (job-line ,state ,pod ,job))
(section (details nil)
(indent
(job-detail ,state ,pod ,job))))))
(kubernetes-ast-define-component jobs-list (state &optional hidden)
(-let (((state-set-p &as &alist 'items jobs) (kubernetes-state--get state 'jobs))
([fmt labels] kubernetes-jobs--column-heading))
`(section (jobs-container ,hidden)
(header-with-count "Jobs" ,jobs)
(indent
(columnar-loading-container ,jobs
,(propertize
(apply #'format fmt (split-string labels))
'face
'magit-section-heading)
,(--map `(job ,state ,it) jobs)))
(padding))))
;; Requests and state management
(kubernetes-state-define-refreshers jobs)
(defun kubernetes-jobs-delete-marked (state)
(let ((names (kubernetes-state--get state 'marked-jobs)))
(dolist (name names)
(kubernetes-state-delete-job name)
(kubernetes-kubectl-delete "job" name kubernetes-props state
(lambda (_)
(message "Deleting job %s succeeded." name))
(lambda (_)
(message "Deleting job %s failed" name)
(kubernetes-state-mark-job name))))
(kubernetes-state-trigger-redraw)))
;; Displaying jobs
(defun kubernetes-jobs--read-name (state)
"Read a job name from the user.
STATE is the current application state.
Update the job state if it not set yet."
(-let* (((&alist 'items jobs)
(or (kubernetes-state--get state 'jobs)
(progn
(message "Getting jobs...")
(let ((response (kubernetes-kubectl-await-on-async kubernetes-props state (-partial #'kubernetes-kubectl-get "jobs"))))
(kubernetes-state-update-jobs response)
response))))
(jobs (append jobs nil))
(names (-map #'kubernetes-state-resource-name jobs)))
(completing-read "Job: " names nil t)))
;;;###autoload
(defun kubernetes-display-job (job-name state)
"Display information for a job in a new window.
STATE is the current application state.
JOB-NAME is the name of the job to display."
(interactive (let ((state (kubernetes-state)))
(list (kubernetes-jobs--read-name state) state)))
(if-let (job (kubernetes-state-lookup-job job-name state))
(select-window
(display-buffer
(kubernetes-yaml-make-buffer kubernetes-display-job-buffer-name job)))
(error "Unknown job: %s" job-name)))
(provide 'kubernetes-jobs)
;;; kubernetes-jobs.el ends here