-
Notifications
You must be signed in to change notification settings - Fork 51
/
Copy pathcirce.el
3987 lines (3506 loc) · 150 KB
/
circe.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; circe.el --- Client for IRC in Emacs
;; Copyright (C) 2005 - 2013 Jorgen Schaefer
;; Version: 1.3
;; Keywords: IRC, chat
;; Author: Jorgen Schaefer <[email protected]>
;; URL: https://github.com/jorgenschaefer/circe
;; This file is part of Circe.
;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; Circe is a Client for IRC in Emacs. It integrates well with the rest
;; of the editor, using standard Emacs key bindings and indicating
;; activity in channels in the status bar so it stays out of your way
;; unless you want to use it.
;; Complexity-wise, it is somewhere between rcirc (very minimal) and ERC
;; (very complex).
;; Once installed, you should be able to simply use M-x circe to
;; connect to IRC. See the wiki on the project homepage for a more
;; elaboration configuration options.
;;; Code:
(defvar circe-version "1.3"
"Circe version string.")
(require 'ring)
(require 'timer)
(require 'lui)
(require 'lui-format)
(require 'lcs)
;; Used to be optional. But sorry, we're in the 21st century already.
(require 'lui-irc-colors)
(enable-lui-irc-colors)
(defgroup circe nil
"Yet Another Emacs IRC Client."
:prefix "circe-"
:group 'applications)
;;;;;;;;;;;;;
;;; Faces ;;;
;;;;;;;;;;;;;
;; These come before the `defcustom's since they are used for some of
;; the default values.
(defvar circe-prompt-face 'circe-prompt-face
"The face for the Circe prompt.")
(defface circe-prompt-face
'((t (:weight bold :foreground "Black" :background "LightSeaGreen")))
"The face for the Circe prompt."
:group 'circe)
(defvar circe-server-face 'circe-server-face
"The face used to highlight server messages.")
(defface circe-server-face
'((((type tty)) :foreground "blue" :weight bold)
(t (:foreground "SteelBlue")))
"The face used to highlight server messages."
:group 'circe)
(defvar circe-highlight-nick-face 'circe-highlight-nick-face
"The face used to highlight messages directed to us.")
(defface circe-highlight-nick-face
'((((type tty)) (:foreground "cyan" :weight bold))
(t (:foreground "CadetBlue3" :weight bold)))
"The face used to highlight messages directed to us."
:group 'circe)
(defvar circe-my-message-face 'circe-my-message-face
"The face used to highlight our own messages.")
(defface circe-my-message-face '((t))
"The face used to highlight our own messages."
:group 'circe)
(defvar circe-originator-face 'circe-originator-face
"The face used to highlight the originator of a message.")
(defface circe-originator-face '((t))
"The face used to highlight the originator of a message."
:group 'circe)
(defvar circe-topic-diff-new-face 'circe-topic-diff-new-face
"The face used for text added to a topic.
See the {topic-diff} parameter to `circe-format-server-topic'.")
(defface circe-topic-diff-new-face '((t (:background "DarkGreen")))
"The face used for text added to a topic.
See the {topic-diff} parameter to `circe-format-server-topic'."
:group 'circe)
(defvar circe-topic-diff-removed-face 'circe-topic-diff-removed-face
"The face used for text removed from a topic.
See the {topic-diff} parameter to `circe-format-server-topic'.")
(defface circe-topic-diff-removed-face '((t (:background "DarkRed")))
"The face used for text removed from a topic.
See the {topic-diff} parameter to `circe-format-server-topic'."
:group 'circe)
(defvar circe-fool-face 'circe-fool-face
"The face used for fools.
See `circe-fool-list'.")
(defface circe-fool-face
'((((type tty)) (:foreground "grey40" :bold t))
(((type x)) (:foreground "grey40")))
"The face used for fools.
See `circe-fool-list'."
:group 'circe)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Customization Variables ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defcustom circe-default-nick (user-login-name)
"The default nick for circe."
:type 'string
:group 'circe)
(defcustom circe-default-user circe-default-nick
"The default user name for circe."
:type 'string
:group 'circe)
(defcustom circe-default-realname (if (string= (user-full-name) "")
circe-default-nick
(user-full-name))
"The default real name for circe."
:type 'string
:group 'circe)
(defcustom circe-network-options nil
"Network options.
This alist maps network names to respective options.
Common options:
:pass - The IRC server password to use for this network or a function to fetch it.
:nick - The nick name to use (defaults to `circe-default-nick')
:user - The user name to use (defaults to `circe-default-user')
:realname - The real name to use (defaults to `circe-default-realname')
:channels - A plist of channels to join
(see `circe-server-auto-join-channels').
:host - The host name of the server to connect to.
:service - The service name or port for the server.
:tls - A boolean indicating as to whether to use TLS or
not (defaults to nil). If you set this, you'll likely
have to set :service as well.
:nickserv-nick - The nick to authenticate with to nickserv, if configured.
(defaults to the value of :nick)
:nickserv-password - The password to use for nickserv authentication."
:type '(alist :key-type string :value-type plist)
:group 'circe)
(defvar circe-networks
'(("Freenode" :host "irc.freenode.net" :port (6667 . 6697)
:nickserv-mask "^NickServ!NickServ@services\\.$"
:nickserv-identify-challenge "\C-b/msg\\s-NickServ\\s-identify\\s-<password>\C-b"
:nickserv-identify-command "PRIVMSG NickServ :IDENTIFY {nick} {password}"
:nickserv-identify-confirmation "^You are now identified for .*\\.$"
:nickserv-ghost-command "PRIVMSG NickServ :GHOST {nick} {password}"
:nickserv-ghost-confirmation "has been ghosted\\.$\\|is not online\\.$"
)
("Coldfront" :host "irc.coldfront.net" :port 6667
:nickserv-mask "^NickServ!services@coldfront\\.net$"
:nickserv-identify-challenge "/msg\\s-NickServ\\s-IDENTIFY\\s-\C-_password\C-_"
:nickserv-identify-command "PRIVMSG NickServ :IDENTIFY {password}"
)
("Bitlbee" :host "localhost"
:nickserv-mask "\\(bitlbee\\|root\\)!\\(bitlbee\\|root\\)@"
:nickserv-identify-challenge "use the \x02identify\x02 command to identify yourself"
:nickserv-identify-command "PRIVMSG &bitlbee :identify {password}"
:nickserv-identify-confirmation "Password accepted, settings and accounts loaded"
)
("OFTC" :host "irc.oftc.net" :port (6667 . 6697)
:nickserv-mask "^NickServ!services@services\\.oftc\\.net$"
:nickserv-identify-challenge "This nickname is registered and protected."
:nickserv-identify-command "PRIVMSG NickServ :IDENTIFY {password} {nick}"
:nickserv-identify-confirmation "^You are successfully identified as .*\\.$"
)
)
"Alist of networks and connection settings.
See the `circe' command for details of this variable.")
(defcustom circe-default-quit-message "Using Circe, the loveliest of all IRC clients"
"The default quit message when no other is given.
This is sent when the server buffer is killed or when /QUIT is
given with no argument."
:type 'string
:group 'circe)
(defcustom circe-default-part-message "Using Circe, the loveliest of all IRC clients"
"How to part when a channel buffer is killed, or when no
argument is given to /PART."
:type 'string
:group 'circe)
(defcustom circe-new-buffer-behavior 'display
"How new buffers should be treated.
'display - Show them, but don't select them
'switch - Switch to that buffer
'ignore - Just open it
Also see `circe-new-buffer-behavior-ignore-auto-joins'."
:type '(choice (const :tag "Display" display)
(const :tag "Switch" switch)
(const :tag "Ignore" ignore))
:group 'circe)
(defcustom circe-new-buffer-behavior-ignore-auto-joins nil
"Don't show channel buffers when they were auto-joined.
When t, the value of `circe-new-buffer-behavior' will be ignored
for auto-joined channel buffers."
:type 'boolean
:group 'circe)
(defcustom circe-auto-query-p t
"Non-nil if queries should be opened automatically."
:type 'boolean
:group 'circe)
(defcustom circe-auto-query-max 23
"The maximum number of queries which are opened automatically.
If more messages arrive - typically in a flood situation - they
are displayed as if `circe-auto-query-p' was nil."
:type 'integer
:group 'circe)
(defcustom circe-use-cycle-completion nil
"Whether Circe should use cycle completion.
If this is not nil, Circe will set `completion-cycle-threshold'
to t locally in Circe buffers, enabling cycle completion for
nicks no matter what completion style you use in the rest of
Emacs. If you set this to nil, Circe will not touch your default
completion style.
NOTE: Emacs 24.2 and before have a bug related to cycle
completion. If you enable cycle completion in those Emacsen, you
should also (require 'circe-fix-minibuffer). This is a backported
minibuffer.el from 24.3, though, so do this at your own
discretion.
See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=12619 for a
discussion of the bug."
:type 'boolean
:group 'circe)
(defcustom circe-reduce-lurker-spam nil
"If enabled, Circe will stop showing some messages.
This means that JOIN, PART, QUIT and NICK messages are not shown
for users on channels that have not spoken yet (\"lurker\"), or
haven't spoken in `circe-active-users-timeout' seconds. When they
speak for the first time, Circe displays their join time."
:type 'boolean
:group 'circe)
(defcustom circe-active-users-timeout nil
"When non-nil, should be the number of seconds after which
active users are regarded as inactive again after speaking."
:type 'integer
:group 'circe)
(defcustom circe-channel-recent-users-timeout (* 20 60)
"Forget about parted users after this many seconds.
If nil, parted users are immediately forgotten about."
:type 'integer
:group 'circe)
(defcustom circe-prompt-string (concat (propertize ">"
'face 'circe-prompt-face)
" ")
"The string to initialize the prompt with.
To change the prompt dynamically or just in specific buffers, use
`lui-set-prompt' in the appropriate hooks."
:type 'string
:group 'circe)
(defcustom circe-highlight-nick-type 'sender
"How to highlight occurrences of our own nick.
'sender - Highlight the nick of the sender
'occurrence - Highlight the occurrences of the nick
'message - Highlight the message without the sender
'all - Highlight the whole line"
:type '(choice (const :tag "Sender" sender)
(const :tag "Occurrences" occurrence)
(const :tag "Message" message)
(const :tag "Whole line" all))
:group 'circe)
(defcustom circe-completion-suffix ": "
"A suffix for completed nicks at the beginning of a line."
:type '(choice (const :tag "The standard suffix" ": "))
:group 'circe)
(defcustom circe-ignore-list nil
"List of regular expressions to ignore.
Each regular expression is matched against nick!user@host."
:type '(repeat regexp)
:group 'circe)
(defcustom circe-fool-list nil
"List of regular expressions for fools.
Each regular expression is matched against nick!user@host.
Messages from such people are still inserted, but not shown. They
can be displayed using \\[lui-toggle-ignored]. If this is not
wanted, set `circe-ignore-hard-p'."
:type '(repeat regexp)
:group 'circe)
(defcustom circe-ignore-functions nil
"A list of functions to check whether we should ignore a message.
These functions get five arguments: NICK, USER, HOST, COMMAND, and ARGS.
If one of them returns a non-nil value, the message is ignored."
:type 'hook
:group 'circe)
(defcustom circe-split-line-length 440
"The maximum length of a single message.
If a message exceeds this size, it is broken into multiple ones.
IRC allows for lines up to 512 bytes. Two of them are CR LF.
And a typical message looks like this:
:[email protected] PRIVMSG #lazybastards :Hello!
You can limit here the maximum length of the \"Hello!\" part.
Good luck."
:type 'integer
:group 'circe)
(defcustom circe-server-flood-margin 10
"A margin on how much excess data we send.
The flood protection algorithm of Circe works like the one
detailed in RFC 2813, section 5.8 \"Flood control of clients\".
* If `circe-server-flood-last-message' is less than the current
time, set it equal.
* While `circe-server-flood-last-message' is less than
`circe-server-flood-margin' seconds ahead of the current
time, send a message, and increase
`circe-server-flood-last-message' by
`circe-server-flood-penalty' for each message."
:type 'integer
:group 'circe)
(defcustom circe-server-flood-penalty 3
"How much we penalize a message.
See `circe-server-flood-margin' for an explanation of the flood
protection algorithm."
:type 'integer
:group 'circe)
(defcustom circe-show-server-modes-p nil
"Whether Circe should show server modes.
This is disabled by default, since server mode changes are almost
always channel modes after a split."
:type 'boolean
:group 'circe)
(defcustom circe-server-max-reconnect-attempts 5
"How often Circe should attempt to reconnect to the server.
If this is 0, Circe will not reconnect at all. If this is nil,
it will try to reconnect forever (not recommended)."
:type 'integer
:group 'circe)
(defcustom circe-server-coding-system (if (and (fboundp 'coding-system-p)
(coding-system-p 'undecided)
(coding-system-p 'utf-8))
'(utf-8 . undecided)
nil)
"Coding systems to use for IRC.
This is either a coding system, which is then used both for
encoding and decoding, or a cons cell with the encoding in the
car and the decoding coding system in the cdr."
:type '(cons (coding-system :tag "Encoding")
(coding-system :tag "Decoding"))
:group 'circe)
(defcustom circe-netsplit-delay 60
"The number of seconds a netsplit may be dormant.
If anything happens with a netsplit after this amount of time,
the user is re-notified."
:type 'number
:group 'circe)
(defcustom circe-server-killed-confirmation 'ask
"How to ask for confirmation when a server buffer is killed.
This can be one of the following values:
ask - Ask the user for confirmation
ask-and-kill-all - Ask the user, and kill all associated buffers
nil - Kill first, ask never"
:type '(choice (const :tag "Ask before killing" ask)
(const :tag "Ask, then kill all associated buffers"
ask-and-kill-all)
(const :tag "Don't ask" nil))
:group 'circe)
(defcustom circe-channel-killed-confirmation 'ask
"How to ask for confirmation when a channel buffer is killed.
This can be one of the following values:
ask - Ask the user for confirmation
nil - Don't ask, just kill"
:type '(choid (const :tag "Ask before killing" ask)
(const :tag "Don't ask" nil))
:group 'circe)
(defcustom circe-track-faces-priorities '(circe-highlight-nick-face
lui-highlight-face
circe-my-message-face
circe-server-face)
"A list of faces which should show up in the tracking.
The first face is kept if the new message has only lower faces,
or faces that don't show up at all."
:type '(repeat face)
:group 'circe)
(defcustom circe-server-send-unknown-command-p nil
"Non-nil when Circe should just pass on commands it doesn't know.
E.g. /fnord foo bar would then just send \"fnord foo bar\" to the
server."
:type 'boolean
:group 'circe)
(defcustom circe-nick-next-function 'circe-nick-next
"A function that maps a nick to a new nick.
This is used when the initial nicks are not used. The default
just appends dashes as long as possible, and then generates
random nicks."
:type 'function
:group 'circe)
(defcustom circe-receive-message-functions nil
"Functions called when a message from the IRC server arrives.
Each function is called with 5 arguments: NICK, USER, HOST,
COMMAND, and ARGS."
:type 'hook
:group 'circe)
(defcustom circe-server-connected-hook nil
"Hook run when we successfully connected to a server.
This is run from a 001 (RPL_WELCOME) message handler."
:type 'hook
:group 'circe)
(defcustom circe-server-mode-hook nil
"Hook run when circe connects to a server."
:type 'hook
:group 'circe)
;;;;;;;;;;;;;;;
;;; Formats ;;;
;;;;;;;;;;;;;;;
(defgroup circe-format nil
"Format strings for Circe.
All these formats always allow the {mynick} and {target} format
strings."
:prefix "circe-format-"
:group 'circe)
(defcustom circe-format-not-tracked '(circe-format-server-message
circe-format-server-notice
circe-format-server-numeric
circe-format-server-topic
circe-format-server-rejoin
circe-format-server-lurker-activity)
"A list of formats that should not trigger tracking."
:type '(repeat symbol)
:group 'circe-format)
(defcustom circe-format-server-message "*** {body}"
"The format for generic server messages.
{body} - The body of the message."
:type 'string
:group 'circe-format)
(defcustom circe-format-self-say "> {body}"
"The format for messages to queries or channels.
{nick} - Your nick.
{body} - The body of the message."
:type 'string
:group 'circe-format)
(defcustom circe-format-self-action "* {nick} {body}"
"The format for actions to queries or channels.
{nick} - Your nick.
{body} - The body of the action."
:type 'string
:group 'circe-format)
(defcustom circe-format-self-message "-> *{target}* {body}"
"The format for messages sent to other people outside of queries.
{target} - The target nick.
{body} - The body of the message."
:type 'string
:group 'circe-format)
(defcustom circe-format-action "* {nick} {body}"
"The format for actions in queries or channels.
{nick} - The nick doing the action.
{body} - The body of the action."
:type 'string
:group 'circe-format)
(defcustom circe-format-message-action "* *{nick}* {body}"
"The format for actions in messages outside of queries.
{nick} - The nick doing the action.
{body} - The body of the action."
:type 'string
:group 'circe-format)
(defcustom circe-format-say "<{nick}> {body}"
"The format for normal channel or query talk.
{nick} - The nick talking.
{body} - The message."
:type 'string
:group 'circe-format)
(defcustom circe-format-message "*{nick}* {body}"
"The format for a message outside of a query.
{nick} - The originator.
{body} - The message."
:type 'string
:group 'circe-format)
(defcustom circe-format-notice "-{nick}- {body}"
"The format for a notice.
{nick} - The originator.
{body} - The notice."
:type 'string
:group 'circe-format)
(defcustom circe-format-server-notice "-Server Notice- {body}"
"The format for a server notice.
{body} - The notice."
:type 'string
:group 'circe-format)
(defcustom circe-format-server-topic "*** Topic change by {origin}: {new-topic}"
"The format for topic changes.
{channel} - Where the topic change happened.
{new-topic} - The new topic.
{old-topic} - The previous topic.
{topic-diff} - A colorized diff of the topics."
:type 'string
:group 'circe-format)
(defcustom circe-format-server-lurker-activity
"*** First activity: {nick} joined {joindelta} ago."
"The format for the first-activity notice of a user.
{nick} - The originator.
{jointime} - The join time of the user (in seconds).
{joindelta} - The duration from joining until now."
:type 'string
:group 'circe-format)
(defcustom circe-format-server-rejoin
"*** Re-join: {nick} ({nick}@{host})"
"The format for the re-join notice of a user.
{nick} - The originator.
{user} - User name of the originator.
{host} - Host name of the originator.
{departuretime} - Time in seconds when the originator had left.
{departuredelta} - Description of the time delta since the originator left."
:type 'string
:group 'circe-format)
;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Private variables ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;
(defvar circe-source-url "https://github.com/jorgenschaefer/circe"
"URL to Circe's source repository")
(defvar circe-server-name nil
"The name of the server we're currently connected to.")
(make-variable-buffer-local 'circe-server-name)
(defvar circe-server-service nil
"The service name or port of the server we're currently connected to.")
(make-variable-buffer-local 'circe-server-service)
(defvar circe-server-network nil
"The network name of the server we're currently connected to.")
(make-variable-buffer-local 'circe-server-network)
(defvar circe-server-nick nil
"Our current nick.")
(make-variable-buffer-local 'circe-server-nick)
(defvar circe-server-user nil
"The current user name.")
(make-variable-buffer-local 'circe-server-user)
(defvar circe-server-realname nil
"The current real name.")
(make-variable-buffer-local 'circe-server-realname)
(defvar circe-server-pass nil
"The password for the current server or a function to recall it.
If a function is set it will be called with the value of `circe-server-name'.
This is required for reconnecting.")
(make-variable-buffer-local 'circe-server-pass)
(defvar circe-server-use-tls nil
"If non-nil, use `open-tls-stream' to connect to the server.")
(make-variable-buffer-local 'circe-server-use-tls)
(defvar circe-server-process nil
"The process of the server connection.")
(make-variable-buffer-local 'circe-server-process)
(defvar circe-nowait-on-connect
(featurep 'make-network-process '(:nowait t))
"Whether to use asynchronous connect.
Use `circe-network-options' to set this, by adding
:nowait-on-connect nil to your options.
Asynchronous connect is not supported by Emacs in certain
configurations (Windows, most notably). If it causes issues for
you in other environments, turn this off and file a bug.")
(defvar circe-server-registered-p nil
"Non-nil when we have registered with the server.")
(make-variable-buffer-local 'circe-server-registered-p)
(defvar circe-server-last-active-buffer nil
"The last active circe buffer.")
(make-variable-buffer-local 'circe-server-last-active-buffer)
(defvar circe-server-chat-buffers nil
"A hash of chat buffers associated with this server.")
(make-variable-buffer-local 'circe-server-chat-buffers)
(defvar circe-server-filter-data nil
"Cache for the data from the server.
This contains only data that has not been processed yet.")
(make-variable-buffer-local 'circe-server-filter-data)
(defvar circe-server-processing-p nil
"Non-nil when we're currently processing a message.
Yep, this is a mutex. Why would one need a mutex in Emacs, a
single-threaded application, you ask? Easy!
When Circe receives a private message, it sets up a new buffer
for this query. This involves calling the LUI setup functions.
These in turn, though, do start flyspell. This involves starting
an external process, in which case Emacs will wait - and when it
waits, it does accept other stuff from, say, network exceptions.
So, if someone sends you two messages quickly after each other,
the word checker is started for the first, but might take long
enough for the second message to be processed first. Nice, isn't
it.")
(make-variable-buffer-local 'circe-server-processing-p)
(defvar circe-display-table nil
"A hash table mapping commands to their display functions.")
(defvar circe-message-handler-table nil
"A hash table mapping commands to their handler function lists.")
(defvar circe-server-quitting-p nil
"Non-nil when quitting from the server.
This is only non-nil when the user is quitting the current
server. See `circe-command-QUIT'.")
(make-variable-buffer-local 'circe-server-quitting-p)
(defvar circe-chat-target nil
"The current target for the buffer.
This is either a channel or a nick name.")
(make-variable-buffer-local 'circe-chat-target)
(defvar circe-nick-syntax-table
(let ((table (make-syntax-table text-mode-syntax-table))
(special (string-to-list "[]\`_^{}|-"))
(digits (string-to-list "0123456789")))
(dolist (char special)
(modify-syntax-entry char "w" table))
table)
"Syntax table to treat nicks as words.
This is not entirely accurate, as exact chars constituting a nick
can vary between networks.")
;;;;;;;;;;;;;;;;;;;
;;; Server Mode ;;;
;;;;;;;;;;;;;;;;;;;
(defvar circe-server-mode-map
(let ((map (make-sparse-keymap)))
(define-key map (kbd "C-c C-j") 'circe-command-JOIN)
(define-key map (kbd "C-c C-r") 'circe-reconnect)
(set-keymap-parent map lui-mode-map)
map)
"The key map for server mode buffers.")
(defun circe-server-mode ()
"The mode for circe server buffers.
This buffer represents a server connection. When you kill it, the
server connection is closed. This will make all associated
buffers unusable. Be sure to use \\[circe-reconnect] if you want
to reconnect to the server.
\\{circe-server-mode-map}"
(lui-mode)
(add-hook 'lui-pre-output-hook 'circe-highlight-nick
nil t)
(setq major-mode 'circe-server-mode
mode-name "Circe Server"
lui-input-function 'circe-chat-input)
(use-local-map circe-server-mode-map)
(lui-set-prompt circe-prompt-string)
(goto-char (point-max))
(setq circe-server-last-active-buffer (current-buffer))
(add-hook 'completion-at-point-functions 'circe-completion-at-point
nil t)
(when circe-use-cycle-completion
(set (make-local-variable 'completion-cycle-threshold)
t))
;; Tab completion should be case-insensitive
(set (make-local-variable 'completion-ignore-case)
t)
(goto-char (point-max))
(setq circe-server-last-active-buffer (current-buffer))
(add-hook 'kill-buffer-hook
'circe-buffer-killed)
(run-hooks 'circe-server-mode-hook))
(defun circe-read-network ()
"Read a host or network name with completion.
This uses `circe-networks' and `circe-network-options' for
network names."
(let ((default-network (if (null circe-network-options)
(caar circe-networks)
(caar circe-network-options)))
(networks nil)
(completion-ignore-case t))
(dolist (network-spec (append circe-network-options
circe-networks))
(push (car network-spec) networks))
(completing-read "Network or host: "
(sort networks 'string-lessp)
nil nil nil nil
default-network)))
(defun circe-parse-options (network-or-server options)
"Turn the arguments to `circe' into hash mapping variable names to values.
NETWORK-OR-SERVER is a string selection a network name. If it's
not found as a network name, it's assumed to be the name of a
server.
OPTIONS is a property list with keyword options. See
`circe-network-options' for a list and further explanation."
(let ((options (append options
(cdr (assoc-string network-or-server
circe-network-options
t))
(cdr (assoc-string network-or-server
circe-networks
t))))
(variables (make-hash-table :test 'eq))
(not-in-hash (make-symbol "not-in-hash/uninterned")))
(while options
(when (not (keywordp (car options)))
(error "Bad options to `circe', expected plist with keywords"))
(let ((keyword (car options))
(value (cadr options))
(variable nil))
(cond
((eq keyword :host)
(setq variable 'circe-server-name))
((memq keyword '(:service :port))
(setq variable 'circe-server-service))
((memq keyword '(:tls :use-tls))
(setq variable 'circe-server-use-tls))
((eq keyword :channels)
(setq variable 'circe-server-auto-join-channels))
((memq keyword '(:pass :nick :user :realname :network))
(setq variable (intern (concat "circe-server-"
(substring (symbol-name keyword)
1)))))
(t
(setq variable (intern (concat "circe-"
(substring (symbol-name keyword)
1))))))
(when (eq not-in-hash (gethash variable variables not-in-hash))
(puthash variable value variables)))
(setq options (cddr options)))
;; Host and network defaults from the main argument
(when (not (gethash 'circe-server-network variables))
(puthash 'circe-server-network network-or-server variables))
(when (not (gethash 'circe-server-name variables))
(puthash 'circe-server-name network-or-server variables))
;; Other defaults from global variables
(when (not (gethash 'circe-server-nick variables))
(puthash 'circe-server-nick circe-default-nick variables))
(when (not (gethash 'circe-server-user variables))
(puthash 'circe-server-user circe-default-user variables))
(when (not (gethash 'circe-server-realname variables))
(puthash 'circe-server-realname circe-default-realname variables))
;; Default values that depend on other variables
(let ((service (gethash 'circe-server-service variables))
(use-tls (gethash 'circe-server-use-tls variables)))
(when (consp service)
(puthash 'circe-server-service
(if use-tls
(cdr service)
(car service))
variables)))
(when (not (gethash 'circe-nickserv-nick variables))
(puthash 'circe-nickserv-nick
(gethash 'circe-server-nick variables)
variables))
variables))
;;;###autoload
(defun circe (network-or-server &rest options)
"Connect to IRC.
Connect to the given network specified by NETWORK-OR-SERVER.
When this function is called, it collects options from the
OPTIONS argument, the user variable `circe-network-options', and
the defaults found in `circe-networks', in this order.
If NETWORK-OR-SERVER is not found in any of these variables, the
argument is assumed to be the host name for the server, and all
relevant settings must be passed via OPTIONS.
All OPTIONS are treated as variables by getting the string
\"circe-\" prepended to their name. This variable is then set
locally in the server buffer.
See `circe-network-options' for a list of common options."
(interactive (list (circe-read-network)))
(let ((variables (circe-parse-options network-or-server options))
host service)
(setq host (gethash 'circe-server-name variables)
service (gethash 'circe-server-service variables))
(when (not service)
(if (called-interactively-p 'any)
(let* ((input (read-from-minibuffer "Port: " "6667"))
(port (string-to-number input)))
(setq service (if (= port 0)
input
port)))
(setq service 6667))
(puthash 'circe-server-service service variables))
(let* ((buffer-name (format "%s:%s" host service))
(server-buffer (generate-new-buffer buffer-name)))
(with-current-buffer server-buffer
(circe-server-mode)
(let ((unknown-variables nil))
(maphash (lambda (variable value)
(if (not (boundp variable))
(setq unknown-variables (cons variable
unknown-variables))
(set (make-local-variable variable)
value)))
variables)
(dolist (var unknown-variables)
(circe-server-message (format "Unknown variable %s, re-check your configuration."
var))))
(circe-reconnect)
(switch-to-buffer server-buffer)))))
(defvar circe-server-buffer nil
"The buffer of the server associated with the current chat buffer.")
(make-variable-buffer-local 'circe-server-buffer)
(defmacro with-circe-server-buffer (&rest body)
"Run BODY with the current buffer being the current server buffer."
(let ((server (make-symbol "server")))
`(let ((,server (cond
((eq major-mode 'circe-server-mode)
(current-buffer))
(circe-server-buffer
circe-server-buffer)
(t
(error "`with-circe-server-buffer' outside of an circe buffer")))))
(when (and ,server ;; Might be dead!
(bufferp ,server)
(buffer-live-p ,server))
(with-current-buffer ,server
,@body)))))
(put 'with-circe-server-buffer 'lisp-indent-function 0)
(defmacro with-circe-chat-buffer (name &rest body)
"Switch to the chat buffer NAME and run BODY there.
If no such buffer exists, do nothing."
(let ((buf (make-symbol "buf")))
`(let ((,buf (circe-server-get-chat-buffer ,name)))
(when ,buf
(with-current-buffer ,buf
,@body)))))
(put 'with-circe-chat-buffer 'lisp-indent-function 1)
(defvar circe-server-reconnect-attempts 0
"The number of reconnect attempts that Circe has done so far.
See `circe-server-max-reconnect-attempts'.")
(make-variable-buffer-local 'circe-server-reconnect-attempts)
(defun circe-reconnect ()
"Reconnect the current server."
(interactive)
(with-circe-server-buffer
(when (or (called-interactively-p 'any) ;; Always reconnect if the user wants it
(not circe-server-max-reconnect-attempts)
(<= circe-server-reconnect-attempts
circe-server-max-reconnect-attempts))
(setq circe-server-reconnect-attempts (+ circe-server-reconnect-attempts
1))
(dolist (proc (list circe-server-process
(get-buffer-process (current-buffer))))
(when (and proc
(process-live-p proc))
;; Remove the sentinel to avoid it reconnecting when we kill
;; it.
(set-process-sentinel proc nil)
;; A tls connection would spam the server buffer, so bind
;; the process to a temp buffer
(with-temp-buffer
(set-process-buffer proc (current-buffer))
(delete-process proc))))
(setq circe-server-registered-p nil
circe-server-filter-data nil
circe-server-flood-queue nil)
(circe-server-message "Connecting...")
(dolist (buf (circe-chat-buffers))
(with-current-buffer buf
(circe-server-message "Connecting...")))
(cond
(circe-server-use-tls
(require 'circe-tls)
;; `circe-tls-make-stream' is using gnutls/openssl to connect
;; via SSL. This requires some different handling than the
;; normal network process.
(circe-tls-make-stream :name circe-server-name
:buffer (current-buffer)
:host circe-server-name
:service circe-server-service
:coding 'raw-text-dos
:filter #'circe-server-filter-function
:sentinel #'circe-server-sentinel
:query-on-exit-flag nil
:success-func #'(lambda (process)
(setq circe-server-process process))
:nowait circe-nowait-on-connect))
(t
(setq circe-server-process
(make-network-process :name circe-server-name
:buffer (current-buffer)
:host circe-server-name
:service circe-server-service
:coding 'raw-text-dos
:nowait circe-nowait-on-connect
:noquery t
:filter #'circe-server-filter-function
:sentinel #'circe-server-sentinel
:keepalive t))
(when (not circe-nowait-on-connect)
(circe-server-sentinel circe-server-process "open")))))))