lsp: restart when gopls is updated

Author: bhcleek

autoload/go/lsp.vim

@@ -7,7 +7,7 @@ scriptencoding utf-8
 let s:lspfactory = {}
 
 function! s:lspfactory.get() dict abort
-  if !has_key(self, 'current') || empty(self.current) || !has_key(self.current, 'job') || empty(self.current.job)
+  if empty(get(self, 'current', {})) || empty(get(self.current, 'job', {}))
     let self.current = s:newlsp()
   endif
 
@@ -138,6 +138,10 @@ function! s:newlsp() abort
       return
     endif
 
+    if get(self, 'exited', 0)
+      return
+    endif
+
     let l:msg = self.newResponse(a:req.id, l:resp)
     call self.write(l:msg)
   endfunction
@@ -305,13 +309,31 @@ function! s:newlsp() abort
     call ch_sendraw(self.job, l:data)
   endfunction
 
-  function! l:lsp.exit_cb(job, exit_status) dict abort
+  function! l:lsp.exit_cb(job, exit_status) dict
+    let self.exited = 1
+    if !get(self, 'restarting', 0)
+      return
+    endif
+
+    let l:queue = self.queue
+
+    let l:workspaces = self.workspaceDirectories
+
     call s:lspfactory.reset()
+    let l:lsp = s:lspfactory.get()
+
+    " restore workspaces
+    call call('go#lsp#AddWorkspaceDirectory', l:workspaces)
+    " * send DidOpen messages for all buffers that have b:did_lsp_open set
+    " TODO(bc): check modifiable and filetype, too?
+    bufdo if get(b:, 'go_lsp_did_open', 0) | if &modified | call go#lsp#DidOpen(expand('%:p')) | else | call go#lsp#DidChange(expand('%:p')) | endif | endif
+    let l:lsp.queue = extend(l:lsp.queue, l:queue)
+    return
   endfunction
-  " explicitly bind close_cb to state so that within it, self will always refer
 
   function! l:lsp.close_cb(ch) dict abort
-    " TODO(bc): does anything need to be done here?
+    " TODO(bc): remove the buffer variables that indicate that gopls has been
+    " informed that the file is open
   endfunction
 
   function! l:lsp.err_cb(ch, msg) dict abort
@@ -767,6 +789,27 @@ function! go#lsp#DebugBrowser() abort
   call go#util#OpenBrowser(printf('http://localhost:%d', l:port))
 endfunction
 
+function! go#lsp#Restart() abort
+  if !go#util#has_job() || len(s:lspfactory) == 0 || !has_key(s:lspfactory, 'current')
+    return
+  endif
+
+  let l:lsp = s:lspfactory.get()
+
+  let l:lsp.restarting = 1
+
+  let l:state = s:newHandlerState('exit')
+
+  let l:msg = go#lsp#message#Shutdown()
+  let l:state.handleResult = funcref('s:noop')
+  let l:retval = l:lsp.sendMessage(l:msg, l:state)
+
+  let l:msg = go#lsp#message#Exit()
+  let l:retval = l:lsp.sendMessage(l:msg, l:state)
+
+  return l:retval
+endfunction
+
 function! s:debug(event, data) abort
   if !go#util#HasDebug('lsp')
     return

autoload/go/lsp/message.vim

@@ -36,6 +36,20 @@ function! go#lsp#message#Initialized() abort
        \ }
 endfunction
 
+function! go#lsp#message#Shutdown() abort
+  return {
+          \ 'notification': 0,
+          \ 'method': 'shutdown',
+       \ }
+endfunction
+
+function! go#lsp#message#Exit() abort
+  return {
+          \ 'notification': 1,
+          \ 'method': 'exit',
+       \ }
+endfunction
+
 function! go#lsp#message#WorkspaceFoldersResult(dirs) abort
   return map(copy(a:dirs), function('s:workspaceFolder', []))
 endfunction

plugin/go.vim

@@ -56,7 +56,7 @@ let s:packages = {
       \ 'gogetdoc':      ['github.com/zmb3/gogetdoc'],
       \ 'goimports':     ['golang.org/x/tools/cmd/goimports'],
       \ 'golint':        ['golang.org/x/lint/golint'],
-      \ 'gopls':         ['golang.org/x/tools/gopls@latest'],
+      \ 'gopls':         ['golang.org/x/tools/gopls@latest', {}, {'after': function('go#lsp#Restart', [])}],
       \ 'gometalinter':  ['github.com/alecthomas/gometalinter'],
       \ 'golangci-lint': ['github.com/golangci/golangci-lint/cmd/golangci-lint'],
       \ 'gomodifytags':  ['github.com/fatih/gomodifytags'],
@@ -136,29 +136,29 @@ function! s:GoInstallBinaries(updateBinaries, ...)
     let l:platform = 'windows'
   endif
 
-  for [binary, pkg] in items(l:packages)
-    let l:importPath = pkg[0]
+  for [l:binary, l:pkg] in items(l:packages)
+    let l:importPath = l:pkg[0]
 
     " TODO(bc): how to support this with modules? Do we have to clone and then
     " install manually? Probably not. I suspect that we can just use GOPATH
     " mode and then do the legacy method.
-    let bin_setting_name = "go_" . binary . "_bin"
+    let bin_setting_name = "go_" . l:binary . "_bin"
 
     if exists("g:{bin_setting_name}")
       let bin = g:{bin_setting_name}
     else
       if go#util#IsWin()
-        let bin = binary . '.exe'
+        let bin = l:binary . '.exe'
       else
-        let bin = binary
+        let bin = l:binary
       endif
     endif
 
     if !executable(bin) || a:updateBinaries == 1
       if a:updateBinaries == 1
-        echo "vim-go: Updating " . binary . ". Reinstalling ". importPath . " to folder " . go_bin_path
+        echo "vim-go: Updating " . l:binary . ". Reinstalling ". importPath . " to folder " . go_bin_path
       else
-        echo "vim-go: ". binary ." not found. Installing ". importPath . " to folder " . go_bin_path
+        echo "vim-go: ". l:binary ." not found. Installing ". importPath . " to folder " . go_bin_path
       endif
 
       if l:importPath =~ "@"
@@ -208,9 +208,13 @@ function! s:GoInstallBinaries(updateBinaries, ...)
           echom "Error installing " . l:importPath . ": " . l:out
         endif
 
+
         call call(Restore_modules, [])
       endif
 
+      if len(l:pkg) > 2
+        call call(get(l:pkg[2], 'after', function('s:noop', [])), [])
+      endif
     endif
   endfor