Improve whitespace handling in Time::Format (#15890)

* Adds support for `%n` and `%t`. They are exactly equivalent to `\n` and `\t`, as in POSIX C `strptime` (when `_XOPEN_SOURCE` is defined) and Ruby `Time.strptime`.
* All ASCII whitespace characters in the pattern now consume zero or more ASCII whitespace characters when parsing. This includes `%n`, `%t`, and the embedded spaces in `%c` and `%r` too.
* The YAML timestamp specification only allows the space character and the tab character (`[ \t]+`), any other whitespace is now disallowed.

Author: HertzDevil

spec/std/time/format_spec.cr

@@ -137,8 +137,8 @@ describe Time::Format do
       # TODO %U
       # TODO %W
       # TODO %s
-      # TODO %n
-      # TODO %t
+      assert_prints t.to_s("%n"), "\n"
+      assert_prints t.to_s("%t"), "\t"
       # TODO %%
 
       assert_prints t.to_s("%%"), "%"
@@ -565,8 +565,26 @@ describe Time::Format do
   # TODO %U
   # TODO %W
   # TODO %s
-  # TODO %n
-  # TODO %t
+
+  it "parses whitespace" do
+    [" ", "\t", "\n", "\v", "\f", "\r", "%n", "%t"].each do |space|
+      parse_time("20250530", "%Y#{space}%m#{space}%d").should eq(Time.utc(2025, 5, 30))
+      parse_time("2025  05  30", "%Y#{space}%m#{space}%d").should eq(Time.utc(2025, 5, 30))
+      parse_time("2025 \t\n\v\f\r05 \t\n\v\f\r30", "%Y#{space}%m#{space}%d").should eq(Time.utc(2025, 5, 30))
+    end
+
+    parse_time("20250530", "%Y \t\n\v\f\r%n%t%m \t\n\v\f\r%n%t%d").should eq(Time.utc(2025, 5, 30))
+    parse_time("2025  05  30", "%Y \t\n\v\f\r%n%t%m \t\n\v\f\r%n%t%d").should eq(Time.utc(2025, 5, 30))
+    parse_time("2025 \t\n\v\f\r05 \t\n\v\f\r30", "%Y \t\n\v\f\r%n%t%m \t\n\v\f\r%n%t%d").should eq(Time.utc(2025, 5, 30))
+
+    parse_time("Fri  Oct  31  23:00:24  2014", "%c").should eq(Time.utc(2014, 10, 31, 23, 0, 24))
+    parse_time("Fri\tOct\n31\v23:00:24\f\r 2014", "%c").should eq(Time.utc(2014, 10, 31, 23, 0, 24))
+
+    parse_time("11:14:01PM", "%r").should eq(Time.utc(1, 1, 1, 23, 14, 1))
+    parse_time("11:14:01  PM", "%r").should eq(Time.utc(1, 1, 1, 23, 14, 1))
+    parse_time("11:14:01 \t\n\v\f\rPM", "%r").should eq(Time.utc(1, 1, 1, 23, 14, 1))
+  end
+
   # TODO %%
   # TODO %v
 

spec/std/yaml/serialization_spec.cr

@@ -384,6 +384,17 @@ describe "YAML serialization" do
 
     it "deserializes time" do
       Time.from_yaml("2010-11-12").should eq(Time.utc(2010, 11, 12))
+
+      t = Time.local(2001, 12, 14, 21, 59, 43, nanosecond: 100000000, location: Time::Location.fixed(-18000))
+      Time.from_yaml("2001-12-14t21:59:43.10-05:00").should eq(t)
+      Time.from_yaml("2001-12-14 21:59:43.10 -5").should eq(t)
+      Time.from_yaml("2001-12-14  21:59:43.10\t\t -5").should eq(t)
+      Time.from_yaml(%(!!timestamp "2001-12-14  21:59:43.10\t\\t -5")).should eq(t)
+
+      expect_raises(YAML::ParseException) { Time.from_yaml(%(!!timestamp "2001-12-14\\f21:59:43.10 -5")) }
+      expect_raises(YAML::ParseException) { Time.from_yaml(%(!!timestamp "2001-12-14\\n21:59:43.10 -5")) }
+      expect_raises(YAML::ParseException) { Time.from_yaml(%(!!timestamp "2001-12-14\\r21:59:43.10 -5")) }
+      expect_raises(YAML::ParseException) { Time.from_yaml(%(!!timestamp "2001-12-14\\v21:59:43.10 -5")) }
     end
 
     it "deserializes bytes" do

src/time/format.cr

@@ -7,6 +7,9 @@ require "./format/parser"
 # being with a percent (`%`) character. Any text not listed as a directive
 # will be passed/parsed through the output/input string.
 #
+# ASCII whitespaces in the pattern string are written verbatim when formatting,
+# and consume any number of ASCII whitespace characters on parsing.
+#
 # The directives are:
 #
 # * **%a**: short day name (Sun, Mon, Tue, ...)
@@ -40,13 +43,15 @@ require "./format/parser"
 # * **%3N**: milliseconds, zero padded (000, 001, ..., 999) (same as **%L**)
 # * **%6N**: microseconds, zero padded (000000, 000001, ..., 999999)
 # * **%9N**: nanoseconds, zero padded (000000000, 000000001, ..., 999999999)
+# * **%n**: same as the newline character (`\n`)
 # * **%N**: second fraction, zero padded. (Same as `%9N` but may consume more than 9 digits while parsing)
 # * **%p**: am-pm (lowercase)
 # * **%P**: AM-PM (uppercase)
 # * **%r**: 12-hour time (03:04:05 AM)
 # * **%R**: 24-hour time (13:04)
 # * **%s**: seconds since unix epoch (see `Time#to_unix`)
 # * **%S**: seconds, zero padded (00, 01, ..., 59)
+# * **%t**: same as the tab character (`\t`)
 # * **%T**: 24-hour time (13:04:05)
 # * **%u**: day of week (Monday is 1, 1..7)
 # * **%V**: ISO calendar week number of the week-based year (01..53)

src/time/format/custom/yaml_date.cr

@@ -4,8 +4,7 @@ struct Time::Format
   # can consist of just the date part, and following it any number of spaces,
   # or 't', or 'T' can follow, with many optional components. So, we implement
   # this in a more efficient way to avoid parsing the same string with many
-  # possible formats (there's also no way to specify any number of spaces
-  # with Time::Format, or an "or" like in a Regex).
+  # possible formats (there's also no way to specify an "or" like in a Regex).
   #
   # As an additional note, Ruby's Psych YAML parser also implements a
   # custom time parser, probably for this same reason.
@@ -63,8 +62,8 @@ struct Time::Format
       when 'T', 't'
         next_char
         return yaml_time?
-      when .ascii_whitespace?
-        skip_spaces
+      when ' ', '\t'
+        skip_whitespaces_and_tabs
 
         if @reader.has_next?
           return yaml_time?
@@ -99,7 +98,7 @@ struct Time::Format
 
       second_fraction?
 
-      skip_spaces
+      skip_whitespaces_and_tabs
 
       if @reader.has_next?
         begin
@@ -113,6 +112,12 @@ struct Time::Format
 
       true
     end
+
+    private def skip_whitespaces_and_tabs
+      while current_char.in?(' ', '\t')
+        next_char
+      end
+    end
   end
 
   struct Formatter

src/time/format/parser.cr

@@ -502,6 +502,11 @@ struct Time::Format
     end
 
     def char(char, *alternatives)
+      if char.ascii_whitespace?
+        skip_spaces
+        return
+      end
+
       unless @reader.has_next?
         if alternatives.empty?
           raise "Expected #{char.inspect} but the end of the input was reached"

src/time/format/pattern.cr

@@ -54,6 +54,8 @@ struct Time::Format
           month_zero_padded
         when 'M'
           minute
+        when 'n'
+          char '\n'
         when 'N'
           second_fraction
         when 'p'
@@ -68,6 +70,8 @@ struct Time::Format
           unix_seconds
         when 'S'
           second
+        when 't'
+          char '\t'
         when 'T', 'X'
           twenty_four_hour_time_with_seconds
         when 'u'