Support arbitrary IOs in Spec::CLI (#15882)

This continues the effort to make `Spec` more modular and testable.

Colorization state is still global and will be addressed in a subsequent change.

Author: HertzDevil

src/spec.cr

@@ -102,13 +102,14 @@ module Spec
         junit_formatter = Spec::JUnitFormatter.file(Path.new(output_path.not_nil!))
         add_formatter(junit_formatter)
       when "verbose"
-        override_default_formatter(Spec::VerboseFormatter.new)
+        override_default_formatter(Spec::VerboseFormatter.new(@stdout))
       when "tap"
-        override_default_formatter(Spec::TAPFormatter.new)
+        override_default_formatter(Spec::TAPFormatter.new(@stdout))
       end
     end
 
     def main(args)
+      # TODO: should not be global state
       Colorize.on_tty_only!
 
       begin
@@ -118,12 +119,11 @@ module Spec
       end
 
       unless args.empty?
-        STDERR.puts "Error: unknown argument '#{args.first}'"
-        exit 1
+        abort "Error: unknown argument '#{args.first}'"
       end
 
       if ENV["SPEC_VERBOSE"]? == "1"
-        override_default_formatter(Spec::VerboseFormatter.new)
+        override_default_formatter(Spec::VerboseFormatter.new(@stdout))
       end
 
       add_split_filter ENV["SPEC_SPLIT"]?

src/spec/cli.cr

@@ -17,6 +17,12 @@ module Spec
     getter? dry_run = false
     getter? list_tags = false
 
+    getter stdout : IO
+    getter stderr : IO
+
+    def initialize(@stdout : IO = STDOUT, @stderr : IO = STDERR)
+    end
+
     def add_location(file, line)
       locations = @locations ||= {} of String => Array(Int32)
       locations.put_if_absent(File.expand_path(file)) { [] of Int32 } << line
@@ -69,8 +75,7 @@ module Spec
           if location =~ /\A(.+?)\:(\d+)\Z/
             add_location $1, $2.to_i
           else
-            STDERR.puts "location #{location} must be file:line"
-            exit 1
+            abort "location #{location} must be file:line"
           end
         end
         opts.on("--tag TAG", "run examples with the specified TAG, or exclude examples by adding ~ before the TAG.") do |tag|
@@ -92,7 +97,7 @@ module Spec
           configure_formatter("junit", output_path)
         end
         opts.on("-h", "--help", "show this help") do |pattern|
-          puts opts
+          @stdout.puts opts
           exit
         end
         opts.on("-v", "--verbose", "verbose output") do
@@ -102,9 +107,11 @@ module Spec
           configure_formatter("tap")
         end
         opts.on("--color", "Enabled ANSI colored output") do
+          # TODO: should not be global state
           Colorize.enabled = true
         end
         opts.on("--no-color", "Disable ANSI colored output") do
+          # TODO: should not be global state
           Colorize.enabled = false
         end
         opts.on("--dry-run", "Pass all tests without execution") do
@@ -121,6 +128,11 @@ module Spec
     # The real implementation in `../spec.cr` overrides this for actual use.
     def configure_formatter(formatter, output_path = nil)
     end
+
+    private def abort(msg)
+      @stderr.puts msg
+      exit 1
+    end
   end
 
   @[Deprecated("This is an internal API.")]

src/spec/context.cr

@@ -150,7 +150,7 @@ module Spec
     end
 
     def run
-      print_order_message
+      print_order_message(cli.stdout)
 
       internal_run
     end
@@ -174,17 +174,17 @@ module Spec
     def finish(elapsed_time, aborted = false)
       cli.formatters.each(&.finish(elapsed_time, aborted))
       if cli.formatters.any?(&.should_print_summary?)
-        print_summary(elapsed_time, aborted)
+        print_summary(cli.stdout, elapsed_time, aborted)
       end
     end
 
-    def print_summary(elapsed_time, aborted = false)
+    def print_summary(io : IO, elapsed_time, aborted = false)
       pendings = results_for(:pending)
       unless pendings.empty?
-        puts
-        puts "Pending:"
+        io.puts
+        io.puts "Pending:"
         pendings.each do |pending|
-          puts Spec.color("  #{pending.description}", :pending)
+          io.puts Spec.color("  #{pending.description}", :pending)
         end
       end
 
@@ -195,50 +195,50 @@ module Spec
 
       failures_and_errors = failures + errors
       unless failures_and_errors.empty?
-        puts
-        puts "Failures:"
+        io.puts
+        io.puts "Failures:"
         failures_and_errors.each_with_index do |fail, i|
           if ex = fail.exception
-            puts
-            puts "#{(i + 1).to_s.rjust(3, ' ')}) #{fail.description}"
+            io.puts
+            io.puts "#{(i + 1).to_s.rjust(3, ' ')}) #{fail.description}"
 
             if ex.is_a?(SpecError)
               source_line = Spec.read_line(ex.file, ex.line)
               if source_line
-                puts Spec.color("     Failure/Error: #{source_line.strip}", :error)
+                io.puts Spec.color("     Failure/Error: #{source_line.strip}", :error)
               end
             end
-            puts
+            io.puts
 
             message = ex.is_a?(SpecError) ? ex.to_s : ex.inspect_with_backtrace
             message.split('\n') do |line|
-              print "       "
-              puts Spec.color(line, :error)
+              io.print "       "
+              io.puts Spec.color(line, :error)
             end
 
             if ex.is_a?(SpecError)
-              puts
-              puts Spec.color("     # #{Path[ex.file].relative_to(cwd)}:#{ex.line}", :comment)
+              io.puts
+              io.puts Spec.color("     # #{Path[ex.file].relative_to(cwd)}:#{ex.line}", :comment)
             end
           end
         end
       end
 
       if cli.slowest
-        puts
+        io.puts
         results = results_for(:success) + results_for(:fail)
         top_n = results.sort_by { |res| -res.elapsed.not_nil!.to_f }[0..cli.slowest.not_nil!]
         top_n_time = top_n.sum &.elapsed.not_nil!.total_seconds
         percent = (top_n_time * 100) / elapsed_time.total_seconds
-        puts "Top #{cli.slowest} slowest examples (#{top_n_time.humanize} seconds, #{percent.round(2)}% of total time):"
+        io.puts "Top #{cli.slowest} slowest examples (#{top_n_time.humanize} seconds, #{percent.round(2)}% of total time):"
         top_n.each do |res|
-          puts "  #{res.description}"
+          io.puts "  #{res.description}"
           res_elapsed = res.elapsed.not_nil!.total_seconds.humanize
-          puts "    #{res_elapsed.colorize.bold} seconds #{Path[res.file].relative_to(cwd)}:#{res.line}"
+          io.puts "    #{res_elapsed.colorize.bold} seconds #{Path[res.file].relative_to(cwd)}:#{res.line}"
         end
       end
 
-      puts
+      io.puts
 
       success = results_for(:success)
       total = pendings.size + failures.size + errors.size + success.size
@@ -250,27 +250,27 @@ module Spec
                      else                                        Status::Success
                      end
 
-      puts "Aborted!".colorize.red if aborted
-      puts "Finished in #{Spec.to_human(elapsed_time)}"
-      puts Spec.color("#{total} examples, #{failures.size} failures, #{errors.size} errors, #{pendings.size} pending", final_status)
-      puts Spec.color("Only running `focus: true`", :focus) if cli.focus?
+      io.puts "Aborted!".colorize.red if aborted
+      io.puts "Finished in #{Spec.to_human(elapsed_time)}"
+      io.puts Spec.color("#{total} examples, #{failures.size} failures, #{errors.size} errors, #{pendings.size} pending", final_status)
+      io.puts Spec.color("Only running `focus: true`", :focus) if cli.focus?
 
       unless failures_and_errors.empty?
-        puts
-        puts "Failed examples:"
-        puts
+        io.puts
+        io.puts "Failed examples:"
+        io.puts
         failures_and_errors.each do |fail|
-          print Spec.color("crystal spec #{Path[fail.file].relative_to(cwd)}:#{fail.line}", :error)
-          puts Spec.color(" # #{fail.description}", :comment)
+          io.print Spec.color("crystal spec #{Path[fail.file].relative_to(cwd)}:#{fail.line}", :error)
+          io.puts Spec.color(" # #{fail.description}", :comment)
         end
       end
 
-      print_order_message
+      print_order_message(io)
     end
 
-    def print_order_message
+    def print_order_message(io : IO)
       if randomizer_seed = cli.randomizer_seed
-        puts Spec.color("Randomized with seed: #{randomizer_seed}", :order)
+        io.puts Spec.color("Randomized with seed: #{randomizer_seed}", :order)
       end
     end
 

src/spec/dsl.cr

@@ -220,9 +220,9 @@ module Spec
             execute_examples
           end
         rescue ex
-          STDERR.print "Unhandled exception: "
-          ex.inspect_with_backtrace(STDERR)
-          STDERR.flush
+          @stderr.print "Unhandled exception: "
+          ex.inspect_with_backtrace(@stderr)
+          @stderr.flush
           @aborted = true
         ensure
           finish_run unless list_tags?
@@ -273,7 +273,7 @@ module Spec
       return if tag_counts.empty?
       longest_name_size = tag_counts.keys.max_of(&.size)
       tag_counts.to_a.sort_by! { |k, v| {-v, k} }.each do |tag_name, count|
-        puts "#{tag_name.rjust(longest_name_size)}: #{count}"
+        @stdout.puts "#{tag_name.rjust(longest_name_size)}: #{count}"
       end
     end
 

src/spec/formatter.cr

@@ -1,7 +1,7 @@
 module Spec
   # :nodoc:
   abstract class Formatter
-    def initialize(@io : IO = STDOUT)
+    def initialize(@io : IO)
     end
 
     def push(context)
@@ -118,18 +118,16 @@ module Spec
 
   # :nodoc:
   class CLI
-    @formatters = [Spec::DotFormatter.new] of Spec::Formatter
-
     def formatters
-      @formatters
+      @formatters ||= [Spec::DotFormatter.new(@stdout)] of Spec::Formatter
     end
 
     def override_default_formatter(formatter)
-      @formatters[0] = formatter
+      formatters[0] = formatter
     end
 
     def add_formatter(formatter)
-      @formatters << formatter
+      formatters << formatter
     end
   end