Add Lint/UselessDef

Author: nobodywasishere

spec/ameba/rule/lint/useless_def_spec.cr

@@ -0,0 +1,57 @@
+require "../../../spec_helper"
+
+module Ameba::Rule::Lint
+  describe UselessDef do
+    subject = UselessDef.new
+
+    it "passes if an operator method is defined within a class" do
+      expect_no_issues subject, <<-CRYSTAL
+        class Foo
+          def +(other)
+          end
+        end
+        CRYSTAL
+    end
+
+    it "passes if an operator method is defined within an enum" do
+      expect_no_issues subject, <<-CRYSTAL
+        enum Foo
+          def +(other)
+          end
+        end
+        CRYSTAL
+    end
+
+    it "passes if an operator method is defined within a module" do
+      expect_no_issues subject, <<-CRYSTAL
+        module Foo
+          def +(other)
+          end
+        end
+        CRYSTAL
+    end
+
+    it "passes if a top-level operator method has a receiver" do
+      expect_no_issues subject, <<-CRYSTAL
+        def Foo.+(other)
+        end
+        CRYSTAL
+    end
+
+    it "fails if a + operator method is defined top-level" do
+      expect_issue subject, <<-CRYSTAL
+        def +(other)
+        # ^^^^^^^^^^ error: Useless method definition
+        end
+        CRYSTAL
+    end
+
+    it "fails if an index operator method is defined top-level" do
+      expect_issue subject, <<-CRYSTAL
+        def [](other)
+        # ^^^^^^^^^^^ error: Useless method definition
+        end
+        CRYSTAL
+    end
+  end
+end

src/ameba/rule/lint/useless_def.cr

@@ -0,0 +1,48 @@
+module Ameba::Rule::Lint
+  # A rule that disallows useless method definitions.
+  #
+  # For example, this is considered invalid:
+  #
+  # ```
+  # def +(other)
+  # end
+  # ```
+  #
+  # And has to be written within a class, struct, or module:
+  #
+  # ```
+  # class Foo
+  #   def +(other)
+  #   end
+  # end
+  # ```
+  #
+  # YAML configuration example:
+  #
+  # ```
+  # Lint/UselessDef:
+  #   Enabled: true
+  # ```
+  class UselessDef < Base
+    properties do
+      since_version "1.7.0"
+      description "Disallows useless method definitions"
+    end
+
+    MSG = "Useless method definition"
+
+    def test(source)
+      AST::NodeVisitor.new self, source, skip: [
+        Crystal::ClassDef,
+        Crystal::EnumDef,
+        Crystal::ModuleDef,
+      ]
+    end
+
+    def test(source, node : Crystal::Def)
+      return if node.name.chars.any?(&.alphanumeric?) || node.receiver
+
+      issue_for node, MSG
+    end
+  end
+end