Add feed given its url

Author: cruessler

lib/ex_rss_web/feed_live/new.ex

@@ -0,0 +1,69 @@
+defmodule ExRssWeb.FeedLive.New do
+  use ExRssWeb, :live_view
+
+  alias ExRss.{Repo, User}
+  alias ExRss.FeedAdder
+
+  def mount(
+        %{"url" => url},
+        %{"current_user" => current_user},
+        socket
+      ) do
+    candidate =
+      case FeedAdder.discover_feed(url) do
+        {:ok, candidate} -> candidate
+        _ -> nil
+      end
+
+    socket =
+      socket
+      |> assign(:current_user, current_user)
+      |> assign(:candidate, candidate)
+      |> assign(:added_feed, nil)
+
+    {:ok, socket}
+  end
+
+  def mount(
+        _params,
+        _session,
+        socket
+      ) do
+    socket =
+      socket
+      |> assign(:candidate, nil)
+      |> assign(:added_feed, nil)
+
+    {:ok, socket}
+  end
+
+  def handle_event("add_feed", feed_params, socket) do
+    multi =
+      Repo.get!(User, socket.assigns.current_user.id)
+      |> FeedAdder.add_feed(feed_params)
+
+    case Repo.transaction(multi) do
+      {:ok, %{feed: added_feed}} ->
+        socket =
+          socket
+          |> assign(:candidate, nil)
+          |> assign(:added_feed, added_feed)
+
+        {:noreply, socket}
+
+      {:error, _error} ->
+        {:noreply, socket}
+    end
+  end
+
+  def format_frequency(%{seconds: seconds, posts: posts}) do
+    duration =
+      if seconds < 2 * 86400 do
+        "#{(seconds / 3600) |> round} hours"
+      else
+        "#{(seconds / 86400) |> round} days"
+      end
+
+    "#{posts} posts in #{duration}"
+  end
+end

lib/ex_rss_web/feed_live/new.html.heex

@@ -0,0 +1,24 @@
+<%= if @candidate do %>
+  <h1 class="text-m">This feed can be added</h1>
+
+  {@candidate.title}
+
+  <small class="inline-block ml-6">{format_frequency(@candidate.frequency)}</small>
+  <p><code>{@candidate.url}</code></p>
+
+  <button
+    class="px-4 py-2 text-sm font-extrabold bg-blue-700 text-white"
+    type="button"
+    phx-click="add_feed"
+    phx-value-title={@candidate.title}
+    phx-value-url={@candidate.url}
+  >
+    Add
+  </button>
+<% end %>
+
+<%= if @added_feed do %>
+  <h1 class="text-m">This feed has been added</h1>
+
+  <p><code>{@added_feed.url}</code></p>
+<% end %>

lib/ex_rss_web/router.ex

@@ -46,8 +46,7 @@ defmodule ExRssWeb.Router do
 
       scope "/feeds" do
         live "/", FeedLive.Index, :index
-
-        get "/new", FeedController, :new
+        live "/new", FeedLive.New, :new
       end
     end
   end