new wizard ability and basic leaper refactor (#79237)

refactors leapers into basic mobs and adds a new ability for wizards.
for 2 points wizards can buy their own leaper pet. they will get a
contract which lets them pick their pet's name and color

![thefrogs](https://github.com/tgstation/tgstation/assets/138636438/8df9b893-d07d-4e51-a9fa-644830cc7a81)

after they sign the contract they will get a frog statue which is used
to contain the leaper. players can use this statue to release or recall
the leaper into the statue. when its in the statue it will slowly regain
health or even revive from the dead, but if it gets gibbed then the
statue will be useless.

also adds a new ai behavior for leapers which lets them go swim in water
(and splash around) for a period of time. i gave this behavior to frogs
and crabs too

when riding the leaper, the players will get access to all its
abilities, it now has new abilities, it can create frog minions that
suicide bomb the enemies and it can also create a shower of poisonous
structures.

https://github.com/tgstation/tgstation/assets/138636438/931aa7b4-09f0-493f-bdb6-f3bdd0915b22

also when riding the leaper, players can point at walls near it so it
will destroy it. alternatively players can give commands to their
leapers to use abilities and to follow them if they are not riding it.
wizards cant be force dismounted from their frogs, and only wizards can
ride the frogs.

this also removes leapers from cytology as they now are much more
dangerous and have a new home

refactors leapers into basic mobs, and gives more gameplay opportunities
for wizards
:cl:
refactor: leapers have been refactored into basic mobs please report any
bugs
add: wizards can now summon a leaper pet
removal: removes leapers from cytology
/:cl:

Author: Ben10Omintrix

code/__DEFINES/ai/monsters.dm

@@ -188,6 +188,23 @@
 /// the bonfire we will light up
 #define BB_MOOK_BONFIRE_TARGET "bonfire_target"
 
+//leaper keys
+///key holds our volley ability
+#define BB_LEAPER_VOLLEY "leaper_volley"
+///key holds our flop ability
+#define BB_LEAPER_FLOP "leaper_flop"
+///key holds our bubble ability
+#define BB_LEAPER_BUBBLE "leaper_bubble"
+///key holds our summon ability
+#define BB_LEAPER_SUMMON "leaper_summon"
+///key holds the world timer for swimming
+#define BB_KEY_SWIM_TIME "key_swim_time"
+///key holds the water or land target turf
+#define BB_SWIM_ALTERNATE_TURF "swim_alternate_turf"
+///key holds our state of swimming
+#define BB_CURRENTLY_SWIMMING "currently_swimming"
+///key holds how long we will be swimming for
+#define BB_KEY_SWIMMER_COOLDOWN "key_swimmer_cooldown"
 //gutlunch keys
 ///the trough we will eat from
 #define BB_TROUGH_TARGET "trough_target"

code/__DEFINES/is_helpers.dm

@@ -65,6 +65,8 @@ GLOBAL_LIST_INIT(turfs_openspace, typecacheof(list(
 
 #define iscliffturf(A) (istype(A, /turf/open/cliff))
 
+#define iswaterturf(A) (istype(A, /turf/open/water))
+
 //Mobs
 #define isliving(A) (istype(A, /mob/living))
 

code/__DEFINES/research.dm

@@ -58,7 +58,6 @@
 #define CELL_LINE_TABLE_WALKING_MUSHROOM "cell_line_walking_mushroom_table"
 #define CELL_LINE_TABLE_QUEEN_BEE "cell_line_bee_queen_table"
 #define CELL_LINE_TABLE_BUTTERFLY "cell_line_butterfly_table"
-#define CELL_LINE_TABLE_LEAPER	"cell_line_leaper_table"
 #define CELL_LINE_TABLE_MEGA_ARACHNID "cell_line_table_mega_arachnid"
 
 //! All cell virus types

code/__DEFINES/vehicles.dm

@@ -26,6 +26,8 @@
 #define UNBUCKLE_DISABLED_RIDER (1<<3)
 // For fireman carries, the carrying human needs an arm
 #define CARRIER_NEEDS_ARM (1<<4)
+// This rider must be our friend
+#define JUST_FRIEND_RIDERS (1<<5)
 
 //car_traits flags
 ///Will this car kidnap people by ramming into them?

code/_globalvars/lists/xenobiology.dm

@@ -73,11 +73,9 @@ GLOBAL_LIST_INIT_TYPED(cell_line_tables, /list, list(
 	CELL_LINE_TABLE_WALKING_MUSHROOM = list(/datum/micro_organism/cell_line/walking_mushroom = 1),
 	CELL_LINE_TABLE_QUEEN_BEE = list(/datum/micro_organism/cell_line/queen_bee = 1),
 	CELL_LINE_TABLE_BUTTERFLY = list(/datum/micro_organism/cell_line/butterfly = 1),
-	CELL_LINE_TABLE_LEAPER = list(/datum/micro_organism/cell_line/leaper = 1),
 	CELL_LINE_TABLE_MEGA_ARACHNID = list(/datum/micro_organism/cell_line/mega_arachnid = 1),
 	CELL_LINE_TABLE_ALGAE = list(
 		/datum/micro_organism/cell_line/frog = 2,
-		/datum/micro_organism/cell_line/leaper = 2,
 		/datum/micro_organism/cell_line/mega_arachnid = 1,
 		/datum/micro_organism/cell_line/queen_bee = 1,
 		/datum/micro_organism/cell_line/butterfly = 1,

code/datums/ai/basic_mobs/basic_subtrees/go_for_swim.dm

@@ -0,0 +1,59 @@
+#define DEFAULT_TIME_SWIMMER 30 SECONDS
+
+///subtree to go and swim!
+/datum/ai_planning_subtree/go_for_swim
+
+/datum/ai_planning_subtree/go_for_swim/SelectBehaviors(datum/ai_controller/controller, seconds_per_tick)
+	if(controller.blackboard_key_exists(BB_SWIM_ALTERNATE_TURF))
+		controller.queue_behavior(/datum/ai_behavior/travel_towards/swimming, BB_SWIM_ALTERNATE_TURF)
+
+	if(isnull(controller.blackboard[BB_KEY_SWIM_TIME]))
+		controller.set_blackboard_key(BB_KEY_SWIM_TIME, DEFAULT_TIME_SWIMMER)
+
+	var/mob/living/living_pawn = controller.pawn
+	var/turf/our_turf = get_turf(living_pawn)
+
+	// we have been taken out of water!
+	controller.set_blackboard_key(BB_CURRENTLY_SWIMMING, iswaterturf(our_turf))
+
+	if(controller.blackboard[BB_KEY_SWIM_TIME] < world.time)
+		controller.queue_behavior(/datum/ai_behavior/find_and_set/swim_alternate, BB_SWIM_ALTERNATE_TURF, /turf/open)
+		return
+
+	// have some fun in the water
+	if(controller.blackboard[BB_CURRENTLY_SWIMMING] && SPT_PROB(5, seconds_per_tick))
+		controller.queue_behavior(/datum/ai_behavior/perform_emote, "splashes water all around!")
+
+
+///find land if its time to get out of water, otherwise find water
+/datum/ai_behavior/find_and_set/swim_alternate
+
+/datum/ai_behavior/find_and_set/swim_alternate/search_tactic(datum/ai_controller/controller, locate_path, search_range)
+	var/mob/living/living_pawn = controller.pawn
+	if(QDELETED(living_pawn))
+		return null
+	var/look_for_land = controller.blackboard[BB_CURRENTLY_SWIMMING]
+	var/list/possible_turfs = list()
+	for(var/turf/possible_turf in oview(search_range, living_pawn))
+		if(isclosedturf(possible_turf) || isspaceturf(possible_turf) || isopenspaceturf(possible_turf))
+			continue
+		if(possible_turf.is_blocked_turf())
+			continue
+		if(look_for_land == iswaterturf(possible_turf))
+			continue
+		possible_turfs += possible_turf
+
+	if(!length(possible_turfs))
+		return null
+
+	return(pick(possible_turfs))
+
+/datum/ai_behavior/travel_towards/swimming
+	clear_target = TRUE
+
+/datum/ai_behavior/travel_towards/swimming/finish_action(datum/ai_controller/controller, succeeded, target_key)
+	. = ..()
+	var/time_to_add = controller.blackboard[BB_KEY_SWIMMER_COOLDOWN] ? controller.blackboard[BB_KEY_SWIMMER_COOLDOWN] : DEFAULT_TIME_SWIMMER
+	controller.set_blackboard_key(BB_KEY_SWIM_TIME, world.time + time_to_add )
+
+#undef DEFAULT_TIME_SWIMMER

code/datums/components/explode_on_attack.dm

@@ -0,0 +1,40 @@
+/**
+ * Bombs the user after an attack
+ */
+/datum/component/explode_on_attack
+	/// range of bomb impact
+	var/impact_range
+	/// should we be destroyed after the explosion?
+	var/destroy_on_explode
+	/// list of mobs we wont bomb on attack
+	var/list/mob_type_dont_bomb
+
+/datum/component/explode_on_attack/Initialize(impact_range = 1, destroy_on_explode = TRUE, list/mob_type_dont_bomb = list())
+	if(!isliving(parent))
+		return COMPONENT_INCOMPATIBLE
+	src.impact_range = impact_range
+	src.destroy_on_explode = destroy_on_explode
+	src.mob_type_dont_bomb = mob_type_dont_bomb
+
+/datum/component/explode_on_attack/RegisterWithParent()
+	RegisterSignal(parent, COMSIG_HOSTILE_PRE_ATTACKINGTARGET, PROC_REF(bomb_target))
+
+/datum/component/explode_on_attack/UnregisterFromParent()
+	UnregisterSignal(parent, COMSIG_HOSTILE_PRE_ATTACKINGTARGET)
+
+
+/datum/component/explode_on_attack/proc/bomb_target(mob/living/owner, atom/victim)
+	SIGNAL_HANDLER
+
+	if(!isliving(victim))
+		return
+
+	if(is_type_in_typecache(victim, mob_type_dont_bomb))
+		return
+
+	explosion(owner, light_impact_range = impact_range, explosion_cause = src)
+
+	if(destroy_on_explode && owner)
+		qdel(owner)
+	return COMPONENT_HOSTILE_NO_ATTACK
+

code/datums/components/pet_commands/pet_commands_basic.dm

@@ -97,6 +97,22 @@
 	parent.emote("spin")
 	return SUBTREE_RETURN_FINISH_PLANNING
 
+/**
+ * # Pet Command: Use ability
+ * Use an an ability that does not require any targets
+ */
+/datum/pet_command/untargetted_ability
+	///untargetted ability we will use
+	var/ability_key
+
+/datum/pet_command/untargetted_ability/execute_action(datum/ai_controller/controller)
+	var/datum/action/cooldown/ability = controller.blackboard[ability_key]
+	if(!ability?.IsAvailable())
+		return
+	controller.queue_behavior(/datum/ai_behavior/use_mob_ability, ability_key)
+	controller.clear_blackboard_key(BB_ACTIVE_PET_COMMAND)
+	return SUBTREE_RETURN_FINISH_PLANNING
+
 /**
  * # Pet Command: Attack
  * Tells a pet to chase and bite the next thing you point at

code/datums/components/riding/riding.dm

@@ -26,12 +26,16 @@
 	var/list/directional_vehicle_layers = list()
 	/// same as above but instead of layer you have a list(px, py)
 	var/list/directional_vehicle_offsets = list()
+	/// planes of the rider
+	var/list/directional_rider_planes = list()
 	/// allow typecache for only certain turfs, forbid to allow all but those. allow only certain turfs will take precedence.
 	var/list/allowed_turf_typecache
 	/// allow typecache for only certain turfs, forbid to allow all but those. allow only certain turfs will take precedence.
 	var/list/forbid_turf_typecache
 	/// We don't need roads where we're going if this is TRUE, allow normal movement in space tiles
 	var/override_allow_spacemove = FALSE
+	/// can anyone other than the rider unbuckle the rider?
+	var/can_force_unbuckle = TRUE
 
 	/**
 	 * Ride check flags defined for the specific riding component types, so we know if we need arms, legs, or whatever.
@@ -55,7 +59,6 @@
 	if(potion_boost)
 		vehicle_move_delay = round(CONFIG_GET(number/movedelay/run_delay) * 0.85, 0.01)
 
-
 /datum/component/riding/RegisterWithParent()
 	. = ..()
 	RegisterSignal(parent, COMSIG_ATOM_DIR_CHANGE, PROC_REF(vehicle_turned))
@@ -66,7 +69,8 @@
 	RegisterSignal(parent, COMSIG_BUCKLED_CAN_Z_MOVE, PROC_REF(riding_can_z_move))
 	RegisterSignals(parent, GLOB.movement_type_addtrait_signals, PROC_REF(on_movement_type_trait_gain))
 	RegisterSignals(parent, GLOB.movement_type_removetrait_signals, PROC_REF(on_movement_type_trait_loss))
-
+	if(!can_force_unbuckle)
+		RegisterSignal(parent, COMSIG_ATOM_ATTACK_HAND, PROC_REF(force_unbuckle))
 /**
  * This proc handles all of the proc calls to things like set_vehicle_dir_layer() that a type of riding datum needs to call on creation
  *
@@ -81,6 +85,9 @@
 /datum/component/riding/proc/vehicle_mob_unbuckle(datum/source, mob/living/rider, force = FALSE)
 	SIGNAL_HANDLER
 
+	handle_unbuckle(rider)
+
+/datum/component/riding/proc/handle_unbuckle(mob/living/rider)
 	var/atom/movable/movable_parent = parent
 	restore_position(rider)
 	unequip_buckle_inhands(rider)
@@ -100,6 +107,7 @@
 	var/atom/movable/movable_parent = parent
 	handle_vehicle_layer(movable_parent.dir)
 	handle_vehicle_offsets(movable_parent.dir)
+	handle_rider_plane(movable_parent.dir)
 
 	if(rider.pulling == source)
 		rider.stop_pulling()
@@ -129,9 +137,20 @@
 		. = AM.layer
 	AM.layer = .
 
+/datum/component/riding/proc/handle_rider_plane(dir)
+	var/atom/movable/movable_parent = parent
+	var/target_plane = directional_rider_planes["[dir]"]
+	if(isnull(target_plane))
+		return
+	for(var/mob/buckled_mob in movable_parent.buckled_mobs)
+		SET_PLANE_EXPLICIT(buckled_mob, target_plane, movable_parent)
+
 /datum/component/riding/proc/set_vehicle_dir_layer(dir, layer)
 	directional_vehicle_layers["[dir]"] = layer
 
+/datum/component/riding/proc/set_rider_dir_plane(dir, plane)
+	directional_rider_planes["[dir]"] = plane
+
 /// This is called after the ridden atom is successfully moved and is used to handle icon stuff
 /datum/component/riding/proc/vehicle_moved(datum/source, oldloc, dir, forced)
 	SIGNAL_HANDLER
@@ -146,6 +165,7 @@
 		return // runtimed with piggy's without this, look into this more
 	handle_vehicle_offsets(dir)
 	handle_vehicle_layer(dir)
+	handle_rider_plane(dir)
 
 /// Turning is like moving
 /datum/component/riding/proc/vehicle_turned(datum/source, _old_dir, new_dir)
@@ -233,11 +253,14 @@
 
 //BUCKLE HOOKS
 /datum/component/riding/proc/restore_position(mob/living/buckled_mob)
-	if(buckled_mob)
-		buckled_mob.pixel_x = buckled_mob.base_pixel_x
-		buckled_mob.pixel_y = buckled_mob.base_pixel_y
-		if(buckled_mob.client)
-			buckled_mob.client.view_size.resetToDefault()
+	if(isnull(buckled_mob))
+		return
+	buckled_mob.pixel_x = buckled_mob.base_pixel_x
+	buckled_mob.pixel_y = buckled_mob.base_pixel_y
+	var/atom/source = parent
+	SET_PLANE_EXPLICIT(buckled_mob, initial(buckled_mob.plane), source)
+	if(buckled_mob.client)
+		buckled_mob.client.view_size.resetToDefault()
 
 //MOVEMENT
 /datum/component/riding/proc/turf_check(turf/next, turf/current)
@@ -285,6 +308,13 @@
 	SIGNAL_HANDLER
 	return COMPONENT_RIDDEN_ALLOW_Z_MOVE
 
+/datum/component/riding/proc/force_unbuckle(atom/movable/source, mob/living/living_hitter)
+	SIGNAL_HANDLER
+
+	if((living_hitter in source.buckled_mobs))
+		return
+	return COMPONENT_CANCEL_ATTACK_CHAIN
+
 /// Called when our vehicle gains a movement trait, so we can apply it to the riders
 /datum/component/riding/proc/on_movement_type_trait_gain(atom/movable/source, trait)
 	SIGNAL_HANDLER

code/datums/components/riding/riding_mob.dm

@@ -5,7 +5,8 @@
 	var/can_be_driven = TRUE
 	/// If TRUE, this creature's abilities can be triggered by the rider while mounted
 	var/can_use_abilities = FALSE
-	var/list/shared_action_buttons = list()
+	/// list of blacklisted abilities that cant be shared
+	var/list/blacklist_abilities = list()
 
 /datum/component/riding/creature/Initialize(mob/living/riding_mob, force = FALSE, ride_check_flags = NONE, potion_boost = FALSE)
 	if(!isliving(parent))
@@ -60,6 +61,8 @@
 	// for fireman carries, check if the ridden is stunned/restrained
 	else if((ride_check_flags & CARRIER_NEEDS_ARM) && (HAS_TRAIT(living_parent, TRAIT_RESTRAINED) || living_parent.incapacitated(IGNORE_RESTRAINTS|IGNORE_GRAB)))
 		. = FALSE
+	else if((ride_check_flags & JUST_FRIEND_RIDERS) && !(living_parent.faction.Find(REF(rider))))
+		. = FALSE
 
 	if(. || !consequences)
 		return
@@ -153,6 +156,7 @@
 	for(var/mob/yeet_mob in user.buckled_mobs)
 		force_dismount(yeet_mob, (!(user.istate & ISTATE_HARM))) // gentle on help, byeeee if not
 
+
 /// If the ridden creature has abilities, and some var yet to be made is set to TRUE, the rider will be able to control those abilities
 /datum/component/riding/creature/proc/setup_abilities(mob/living/rider)
 	if(!isliving(parent))
@@ -161,6 +165,8 @@
 	var/mob/living/ridden_creature = parent
 
 	for(var/datum/action/action as anything in ridden_creature.actions)
+		if(is_type_in_list(action, blacklist_abilities))
+			continue
 		action.GiveAction(rider)
 
 /// Takes away the riding parent's abilities from the rider
@@ -454,3 +460,35 @@
 	set_vehicle_dir_layer(NORTH, OBJ_LAYER)
 	set_vehicle_dir_layer(EAST, OBJ_LAYER)
 	set_vehicle_dir_layer(WEST, OBJ_LAYER)
+
+/datum/component/riding/creature/leaper
+	can_force_unbuckle = FALSE
+	can_use_abilities = TRUE
+	blacklist_abilities = list(/datum/action/cooldown/toggle_seethrough)
+	ride_check_flags = JUST_FRIEND_RIDERS
+
+/datum/component/riding/creature/leaper/handle_specials()
+	. = ..()
+	set_riding_offsets(RIDING_OFFSET_ALL, list(TEXT_NORTH = list(17, 46), TEXT_SOUTH = list(17,51), TEXT_EAST = list(27, 46), TEXT_WEST = list(6, 46)))
+	set_rider_dir_plane(SOUTH, GAME_PLANE_UPPER)
+	set_rider_dir_plane(NORTH, GAME_PLANE)
+	set_rider_dir_plane(EAST, GAME_PLANE_UPPER)
+	set_rider_dir_plane(WEST, GAME_PLANE_UPPER)
+
+/datum/component/riding/creature/leaper/Initialize(mob/living/riding_mob, force = FALSE, ride_check_flags = NONE, potion_boost = FALSE)
+	. = ..()
+	RegisterSignal(riding_mob, COMSIG_MOB_POINTED, PROC_REF(attack_pointed))
+
+/datum/component/riding/creature/leaper/proc/attack_pointed(mob/living/rider, atom/pointed)
+	SIGNAL_HANDLER
+	if(!isclosedturf(pointed))
+		return
+	var/mob/living/basic/basic_parent = parent
+	if(!basic_parent.CanReach(pointed))
+		return
+	basic_parent.melee_attack(pointed)
+
+
+/datum/component/riding/leaper/handle_unbuckle(mob/living/rider)
+	. = ..()
+	UnregisterSignal(rider,  COMSIG_MOB_POINTED)