Add offline test for calculate-plutus-script-cost command

Author: palas

cardano-cli/cardano-cli.cabal

@@ -353,6 +353,8 @@ test-suite cardano-cli-test
     filepath,
     hedgehog,
     hedgehog-extras,
+    lens,
+    lens-aeson,
     mmorph,
     monad-control,
     parsec,

cardano-cli/test/cardano-cli-test/Test/Cli/Transaction/Build.hs

@@ -1,14 +1,47 @@
+{-# LANGUAGE ScopedTypeVariables #-}
+
 module Test.Cli.Transaction.Build where
 
+import Cardano.Api.Ledger (hashToBytes)
+import Cardano.Api.Shelley
+  ( AddressAny (AddressShelley)
+  , AddressInEra (AddressInEra)
+  , AddressTypeInEra (ShelleyAddressInEra)
+  , AsType (AsAddressAny)
+  , ReferenceScript (ReferenceScriptNone)
+  , ShelleyBasedEra (ShelleyBasedEraConway)
+  , TxId (TxId)
+  , TxIn (TxIn)
+  , TxIx (TxIx)
+  , TxOut (TxOut)
+  , TxOutDatum (TxOutDatumNone)
+  , UTxO (UTxO)
+  , deserialiseAddress
+  , liftIO
+  , lovelaceToTxOutValue
+  , writeFileJSON
+  )
+
+import Control.Lens ((^?))
+import Data.Aeson qualified as Aeson
+import Data.Aeson.Lens qualified as Aeson
+import Data.ByteString.Base16 qualified as Base16
 import Data.List (isInfixOf)
+import Data.Map qualified as Map
+import Data.Text qualified as Text
+import Data.Text.Encoding qualified as Text
 import System.Exit (ExitCode (..))
 import System.FilePath ((</>))
 
+import Test.Gen.Cardano.Api.Typed (genShelleyHash)
+
 import Test.Cardano.CLI.Util
 
 import Hedgehog
 import Hedgehog qualified as H
-import Hedgehog.Extras.Test.Base qualified as H
+import Hedgehog.Extras qualified as H
+import Hedgehog.Gen qualified as Gen
+import Hedgehog.Range qualified as Range
 
 inputDir :: FilePath
 inputDir = "test/cardano-cli-test/files/input/shelley/transaction"
@@ -93,3 +126,86 @@ hprop_conway_transaction_build_raw_negative_bits_positive_total_txout = watchdog
       , "--out-file"
       , outFile
       ]
+
+-- | This tests calculating the cost of a plutus script offline.
+-- @cabal test cardano-cli-test --test-options '-p "/conway calculate plutus script cost offline/"'@
+hprop_conway_calculate_plutus_script_cost_offline :: Property
+hprop_conway_calculate_plutus_script_cost_offline = propertyOnce $ H.moduleWorkspace "tmp" $ \tempDir -> do
+  randomTxIdHash <- forAll genShelleyHash
+  txIx <- forAll $ Gen.integral (Range.linear 0 10)
+  AddressShelley scriptAddr <-
+    H.evalMaybe $
+      deserialiseAddress AsAddressAny "addr_test1wqvxuvh64q9zdqgrjt76d42eclk5wgdxtnsun4808cwg0dqxy2mj0"
+
+  unsignedTx <- H.noteTempFile tempDir "unsigned.tx"
+
+  H.noteShowM_ $
+    execCardanoCLI
+      [ "conway"
+      , "transaction"
+      , "build-raw"
+      , "--tx-in"
+      , Text.unpack (Text.decodeLatin1 (Base16.encode (hashToBytes randomTxIdHash))) <> "#" <> show txIx
+      , "--tx-in-script-file"
+      , "test/cardano-cli-test/files/input/plutus/v3-always-succeeds.plutus"
+      , "--tx-in-redeemer-value"
+      , "42"
+      , "--tx-in-execution-units"
+      , "(30,40)"
+      , "--tx-out"
+      , "addr_test1wqvxuvh64q9zdqgrjt76d42eclk5wgdxtnsun4808cwg0dqxy2mj0+1000000"
+      , "--fee"
+      , "200000"
+      , "--out-file"
+      , unsignedTx
+      ]
+
+  costOutFile <- H.noteTempFile tempDir "cost-calculation.json"
+
+  utxoFile <- H.noteTempFile tempDir "utxo.json"
+  H.evalEitherM $
+    liftIO $
+      writeFileJSON
+        utxoFile
+        ( UTxO $
+            Map.singleton
+              (TxIn (TxId randomTxIdHash) (TxIx txIx))
+              ( TxOut
+                  (AddressInEra (ShelleyAddressInEra ShelleyBasedEraConway) scriptAddr)
+                  (lovelaceToTxOutValue ShelleyBasedEraConway 1200000)
+                  TxOutDatumNone
+                  ReferenceScriptNone
+              )
+        )
+
+  H.noteShowM_ $
+    execCardanoCLI
+      [ "conway"
+      , "transaction"
+      , "calculate-plutus-script-cost"
+      , "--start-time-posix"
+      , "1666656000"
+      , "--protocol-params-file"
+      , "test/cardano-cli-test/files/input/protocol-params-preview.json"
+      , "--utxo-file"
+      , utxoFile
+      , "--unsafe-extend-safe-zone"
+      , "--era-history-file"
+      , "test/cardano-cli-test/files/input/preview-era-history.json"
+      , "--tx-file"
+      , unsignedTx
+      , "--out-file"
+      , costOutFile
+      ]
+
+  json :: Aeson.Value <- H.evalEitherM $ H.readJsonFile costOutFile
+
+  lovelaceCost <- H.evalMaybe $ json ^? Aeson.nth 0 . Aeson.key "lovelaceCost" . Aeson._Number
+  lovelaceCost === 34
+
+  executionUnits <- H.evalMaybe $ json ^? Aeson.nth 0 . Aeson.key "executionUnits"
+  memory <- H.evalMaybe $ executionUnits ^? Aeson.key "memory" . Aeson._Number
+  memory === 500
+
+  steps <- H.evalMaybe $ executionUnits ^? Aeson.key "steps" . Aeson._Number
+  steps === 64100

cardano-cli/test/cardano-cli-test/files/input/plutus/v3-always-succeeds.plutus

@@ -0,0 +1,5 @@
+{
+    "type": "PlutusScriptV3",
+    "description": "Always succeeds",
+    "cborHex": "46450101002499"
+}

cardano-cli/test/cardano-cli-test/files/input/preview-era-history.json

@@ -0,0 +1,5 @@
+{
+    "type": "EraHistory",
+    "description": "",
+    "cborHex": "9f838300000083000000841910e0194e2083001903608100190360838300000083000000841a000151801903e883001965408100196540838300000083000000841a000151801903e883001965408100196540838300000083000000841a000151801903e8830019654081001965408383000000831b0398dd06d5c800001a0003f48003841a000151801903e88300196540810019654083831b0398dd06d5c800001a0003f4800383c2490306949515279000001a0353a900190286841a000151801903e8830019654081001965408383c2490306949515279000001a0353a90019028683c249040992bf0147d000001a04706d0019035e841a000151801903e883001965408100196540ff"
+}