Add support for dhcp server pools

[cipherbullet]

Hi,
I am trying to create dhcp server using restconf(as I don't see any resources for that)
when I do using curl, it works but when I do using restconf, it returns internal error!

this is my resource block:

resource "iosxe_restconf" "dhcp_pool_switch" {
    path = "Cisco-IOS-XE-native:native/ip/dhcp/pool"

    attributes = {
        "id" = "switch"
        "option.option-range.0.option-range" = 66
        "option.option-range.0.ascii-new" = "172.31.0.1"
        "option.option-range.0.ascii" = "172.31.0.1"

        "default-router.default-router-list.0" = "172.31.0.1"
        "dns-server.dns-server-list.0" = "172.31.0.1"
        
        "network.primary-network.number" = "172.31.0.0"
        "network.primary-network.mask" = "255.255.255.192"
    }
}

I even removed all options to test creation but there is no difference. I mean like this:

resource "iosxe_restconf" "dhcp_pool_switch" {
    path = "Cisco-IOS-XE-native:native/ip/dhcp/pool"

    attributes = {
        "id" = "switch"
    }
}

[danischm]

This should be the correct syntax:

resource "iosxe_restconf" "dhcp_pool_switch" {
  path = "Cisco-IOS-XE-native:native/ip/dhcp/Cisco-IOS-XE-dhcp:pool=switch"

  attributes = {
    id                               = "switch"
    "network/primary-network/number" = "172.31.0.0"
    "network/primary-network/mask"   = "255.255.255.192"
  }

  lists = [
    {
      name = "option/option-range"
      key  = "option-range"
      items = [{
        option-range = "66"
        ascii        = "172.31.0.1"
      }]
    },
    {
      name   = "default-router/default-router-list"
      key = ""
      values = ["172.31.0.1"]
    },
    {
      name   = "dns-server/dns-server-list"
      key = ""
      values = ["172.31.0.1"]
    }
  ]
}

[danischm]

I will keep this issue open to track the addition of a native resource.

[cipherbullet]

Honestly, I did it like this and it works:
but I also can try yours

resource "iosxe_restconf" "dhcp_pool_switch" {
  path = "Cisco-IOS-XE-native:native/ip/dhcp/Cisco-IOS-XE-dhcp:pool=switch"

  attributes = {
    "id"                                   = "switch"
    "network.primary-network.number"       = split("/", local.switch_cidr)[0]
    "network.primary-network.mask"         = local.switch_mask
    "default-router.default-router-list.0" = local.switch_ip
    "dns-server.dns-server-list.0"         = local.switch_ip

    "option.option-range.0.option-range" = 66
    "option.option-range.0.ascii-new"    = local.tftp_server_ip
    "option.option-range.0.ascii"        = local.tftp_server_ip

    "option.option-range.1.option-range" = 67
    "option.option-range.1.ascii-new"    = local.tftp_server_file
    "option.option-range.1.ascii"        = local.tftp_server_file
  }
}

[danischm]

The .0. syntax works to push the config, but it fails to correctly read the config and you will have a constant drift when re-running Terraform.