Prevent non-umbrella project-local plugins

Only umbrella projects can have these.

Author: ferd

src/rebar_plugins.erl

@@ -190,7 +190,7 @@ discover_plugins(_, State) ->
     %% TODO: only support this mode in an umbrella project to avoid cases where
     %% this is used in a project intended to be an installed dependency and accidentally
     %% relies on vendoring when not intended.
-    case lists:member(global, rebar_state:current_profiles(State)) of
+    case lists:member(global, rebar_state:current_profiles(State)) orelse not is_umbrella(State) of
         true ->
             [];
         false ->
@@ -213,6 +213,24 @@ discover_plugins(_, State) ->
             rebar_utils:sort_deps(SetUp)
     end.
 
+is_umbrella(State) ->
+    %% We can't know if this is an umbrella project before running app discovery,
+    %% but plugins are installed before app discovery. So we do a heuristic.
+    %% The lib dirs we search contain things such as apps/, lib/, etc.
+    %% which contain sub-applications. Then there's a final search for the
+    %% local directory ("."), which finds the top-level app in a non-umbrella
+    %% project.
+    %%
+    %% So what we do here is look for the library directories without the ".",
+    %% and if none of these paths exist but one of the src_dirs exist, then
+    %% we know this is not an umbrella application.
+    Root = rebar_dir:root_dir(State),
+    LibPaths = rebar_dir:lib_dirs(State) -- ["."],
+    SrcPaths = rebar_dir:src_dirs(rebar_state:opts(State), ["src"]),
+    lists:any(fun(Dir) -> [] == filelib:wildcard(filename:join(Root, Dir)) end, LibPaths)
+    andalso
+    lists:all(fun(Dir) -> not filelib:is_dir(filename:join(Root, Dir)) end, SrcPaths).
+
 prepare_plugin(AppInfo) ->
     %% We need to handle plugins as dependencies to avoid re-building them
     %% continuously. So here we copy the app directories to the dep location

test/rebar_plugins_SUITE.erl

@@ -19,7 +19,8 @@
          use_checkout_plugins/1,
          %% project-local plugins
          complex_local_plugins/1,
-         complex_local_project_plugins/1
+         complex_local_project_plugins/1,
+         local_plugins_umbrella_only/1
         ]).
 
 -include_lib("common_test/include/ct.hrl").
@@ -44,7 +45,7 @@ end_per_testcase(_, _Config) ->
 all() ->
     [compile_plugins, compile_global_plugins, complex_plugins, list, upgrade, upgrade_project_plugin,
      sub_app_plugins, sub_app_plugin_overrides, project_plugins, use_checkout_plugins,
-     complex_local_plugins, complex_local_project_plugins].
+     complex_local_plugins, complex_local_project_plugins, local_plugins_umbrella_only].
 
 %% Tests that compiling a project installs and compiles the plugins of deps
 compile_plugins(Config) ->
@@ -527,3 +528,55 @@ complex_local_project_plugins(Config) ->
 
     meck:unload(rebar_dir).
 
+local_plugins_umbrella_only(Config) ->
+    BaseDir = ?config(apps, Config),
+    AppName = rebar_test_utils:create_random_name("app1_"),
+    AppDir = BaseDir,
+    LocalPluginName = rebar_test_utils:create_random_name("localplugin1_"),
+    PluginDir = filename:join([BaseDir, "plugins", LocalPluginName]),
+
+    meck:new(rebar_dir, [passthrough]),
+
+    Vsn = rebar_test_utils:create_random_vsn(),
+    Vsn2 = rebar_test_utils:create_random_vsn(),
+    rebar_test_utils:create_app(AppDir, AppName, Vsn, [kernel, stdlib]),
+    rebar_test_utils:create_app(PluginDir, LocalPluginName, Vsn, [kernel, stdlib]),
+
+    DepName = rebar_test_utils:create_random_name("dep1_"),
+    DepName2 = rebar_test_utils:create_random_name("dep2_"),
+    DepName3 = rebar_test_utils:create_random_name("dep3_"),
+    DepName4 = rebar_test_utils:create_random_name("dep4_"),
+    PluginName = rebar_test_utils:create_random_name("plugin1_"),
+
+    Deps = rebar_test_utils:expand_deps(git, [{PluginName, Vsn2, [{DepName2, Vsn,
+                                                                  [{DepName3, Vsn, []}]}]}
+                                             ,{DepName, Vsn, [{DepName4, Vsn, []}]}]),
+    {SrcDeps, _} = rebar_test_utils:flat_deps(Deps),
+    mock_git_resource:mock([{deps, SrcDeps}]),
+
+    RootConfFile =
+        rebar_test_utils:create_config(BaseDir,
+                                       [{plugins, [list_to_atom(LocalPluginName)]}]),
+    rebar_test_utils:create_config(
+        PluginDir,
+        [{deps, [{list_to_atom(DepName),
+                  {git, "http://site.com/user/"++DepName++".git", {tag, Vsn}}}]},
+         {plugins, [{list_to_atom(PluginName),
+                     {git, "http://site.com/user/"++PluginName++".git", {tag, Vsn2}}}
+                   ]}]
+    ),
+    {ok, RConf} = file:consult(RootConfFile),
+
+    %% Build with deps.
+    rebar_test_utils:run_and_check(
+        Config, RConf, ["compile"],
+        {ok, [{app, AppName},
+              {plugin_not_exist, LocalPluginName},
+              {plugin_not_exist, PluginName},
+              {plugin_not_exist, DepName2},
+              {plugin_not_exist, DepName3},
+              {plugin_not_exist, DepName4},
+              {plugin_not_exist, DepName}]}
+     ),
+
+    meck:unload(rebar_dir).